
1. Введение
Курс "программирование графических процессоров" посвящён знакомству с технологией NVIDIA CUDA. CUDA (Compute Unified Device Architecture) – программно-аппаратная технология позволяющая использовать графические процессоры для решения задач общего назначения, а не только для задач обработки графики, она хорошо зарекомендовала себя в задачах моделирования (медицина, химия, ядерная физика, гидродинамика, аэродинамика и многие другие области исследований), машинного обучения и других.
Для прохождения курса понадобится видеокарта NVIDIA с поддержкой технологии CUDA. Поддерживает ли ваша видеокарта технологию CUDA, можно узнать в её спецификации на официальном сайте NVIDIA или в документах, идущих в комплекте с видеокартой. Кроме видеокарты вам понадобится установить CUDA Toolkit, компилятор с языка программирования C, текстовый редактор. На сайте NVIDIA есть инструкции для установки CUDA Toolkit под Windows, Linux и Mac OS X.
Если у вас нет такой видеокарты или нет возможности её использовать, напишите на электронный адрес mileschko.sibsutis@yandex.ru с просьбой выдать логин и пароль для подключения к серверу университета (не забудьте указать свои фамилию, имя, отчество и группу). На нём вы сможете выполнять задания курса. Доступ к серверу осуществляется по протоколу ssh, поэтому вам потребуется ssh клиент для подключения. В ОС Windows можно воспользоваться PuTTY или любым другим клиентом. В Unix-like операционных системах вероятнее всего уже установлена консольная утилита ssh, если нет, установите её из репозиториев вашего дистрибутива или воспользуйтесь любым другим доступным клиентом. И убедитесь, что ваше сетевое соединение стабильно, это необходимо для комфортной работы, протокол ssh очень к этому чувствителен.
[bookmark: header-n8]2. Отличия GPU от CPU
GPU (graphics processing unit, графический процессор) – устройство предназначенное для вычислений с высокой степенью параллелизма и абсолютно не подходит для сложных последовательных вычислений в силу своих архитектурных особенностей. Из-за этого GPU используется как вспомогательный сопроцессор, на котором исполняется параллельный код, а центральный процессор исполняет последовательный код и взаимодействует с остальными устройствами системы. Такая организация вычислений называется "гибридные вычисления", а система на которой реализуются гибридные вычисления – гетерогенной аппаратной вычислительной структурой (системой). Т.е. по своей сути это некоторая комбинация различных по принципу работы вычислительных устройств, объединённых в одну систему. В данный момент гибридные вычисления и гетерогенные системы чаще всего используются в контексте систем, использующих тандем CPU и GPU, но существуют и другие, в качестве примера можно привести системы с процессорами IBM Cell.
Архитектура GPU сильно отличается от архитектуры CPU. Физическая модель CPU состоит из нескольких вычислительных ядер с высокой производительностью, исполняющие по 1-2 вычислительных потока, и памяти – кэша. При этом площадь, которую занимает кэш, больше чем площадь, занимаемая вычислительными ядрами, потому что задержки в вычислениях связанные с обращениями в медленную память (DRAM) CPU пытается скрыть, помещая часто используемые данные в кэш - небольшую область памяти с очень быстрым доступом.
[image: D:\docs\cuda\new cuda\CPU.png]
Рис. 1 – Физическая модель CPU
Архитектура GPU состоит из чипов памяти DRAM, L2 кэша и нескольких мультипроцессоров (SM), работающих независимо друг от друга. И наибольшую площадь занимают именно вычислительные блоки, а не память. Каждый SM представляет собой блок вычислителей с ресурсами. SM состоит из блока регистров, L1 кэша, константного кэша, текстурного кэша, разделяемой памяти (адресуемая область памяти, со скоростью доступа сопоставимой со скоростью доступа к данным из L1 кэша), большого количества CUDA ядер, блоков чтения/записи (LD/ST unit), множества блоков для вычисления специальных функций (SFU), занимающихся вычислением функций, значения которых находятся приближённо, например разложением в ряд (sin, cos, sqrt, exp и т.д.) и 2-4 планировщика варпов, по сути занимающихся распределением машинных команд по вычислительным ядрам. CUDA ядра состоят из множества блоков обрабатывающих операции над целыми числами (INT unit), множества блоков обрабатывающих операции над числами с плавающей точкой одинарной точности (FPU32) и множества блоков обрабатывающих операции над числами с плавающей точкой двойной точности (FPU64). Т.е. в отличие от CPU вычислительные ядра которого исполняют по 1-2 вычислительных потока, вычислительные ядра GPU могут исполнять тысячи вычислительных потоков, называемых нитями, но при этом вычислительные ядра GPU значительно уступают в производительности. Поэтому чтобы добиться наибольшего ускорения решения задачи при помощи GPU нужно разбить её на очень большое количество подзадач, чтобы использовать как можно больше вычислительных ядер GPU. Если этого не сделать, то последовательный алгоритм исполняемый на CPU может работать быстрее за счёт более высокой тактовой частоты вычислительных ядер CPU.

Рис 2 – Физическая модель GPU

Рис. 3 – модель мультипроцессора
Не все нити, исполняющиеся на GPU вычисляются в один момент времени. Нити группируются по 32 нити, такая группа называется варп. Нити находящиеся в одном варпе гарантированно исполняются в один момент времени и исполняют они одинаковую машинную команду, но нити разных варпов не обязательно исполняют одинаковые команды. Такой принцип вычислений очень похож на SIMD - одна команда применяется ко множеству данных, но на GPU он работает в пределах одного варпа, поэтому принцип лежащий в основе обработки данных на GPU назвали SIMT (single instruction, multiple threads) - одна инструкция исполняется множеством нитей. Т.е. исполняемые машинные команды распределяются не по нитям, а сразу по группам нитей – варпам.
Множество инструкций, поддерживаемых GPU зависит от так называемой версии мультипроцессора (compute capability, CC, вычислительная способность). С каждой новой версией CC добавляются новые вычислительные возможности (как правило с сохранением обратной совместимости, т.е. код разработанный под старые архитектуры с большой долей вероятности будет работать и на новой архитектуре) и могут изменяться параметры GPU такие как размеры кэшей, разделяемой памяти, размер варпа (хотя он никогда не менялся и с самых первых версий остаётся равен тридцати двум нитям, в следующих видеокартах его могут изменить).
[bookmark: header-n17]3. Первая программа на CUDA C
Для создания приложений с использованием технологии CUDA потребуется видеокарта NVIDIA, драйвер для видеокарты, набор инструментов разработчика NVIDIA CUDA Tollkit, компилятор языка программирования C, текстовый редактор. Программы с использованием технологии CUDA пишутся в файлах с расширением .cu. Для компиляции используется утилита nvcc. Она компилирует части кода, которые относятся к CUDA API, а остальное отдаёт стандартному компилятору, после чего собирает откомпилированный код в один исполняемый файл.
Пример программы на CUDA C.
hello_world.cu:
#include <stdio.h>
__global__ void kernel () {
	printf("Hello, World!");
}

int main () {
	kernel<<<1,1>>>();
	cudaDeviceSynchronize();
	return 0;
}
Компиляция:
nvcc hello_world.cu -o hello_world
Запуск:
./hello_world
Вывод:
Hello, World
Функция kernel, которая определена в примере называется функция-ядро. Это функция инструкции которой будут выполняться на GPU. Её определения синтаксически не отличается от обычной функции языка программирования C за исключением одного – спецификатора __global__. Именно этот спецификатор указывает на то, что эта функция должна быть скомпилирована для работы на GPU, а не на CPU. Ещё он говорит о том, что функция может быть вызвана из последовательной части кода.
В терминах CUDA API место исполнения параллельного кода называется устройством (device), а место исполнения последовательного кода называется – хост (host). Т.е. функция kernel исполняется на устройстве, но может вызываться на хосте. Помимо спецификатора __global__ существуют спецификаторы __device__ и __host__. Функции помеченные спецификатором __device__ могут исполняться на устройстве и вызываться должны на устройстве, т.е. только из других функций-ядер. Спецификатор __host__ говорит о том, что функция будет исполняться на хосте и вызываться она может только на хосте. Функции помеченные спецификатором __global__ могут вызываться как на хосте так и на устройстве.
Для того чтобы вызвать функцию-ядро, в тройных угловых скобках нужно указать два обязательных параметра, которые показывают сколько всего нитей будет исполнять функцию-ядро. Первый параметр – размер сетки блоков, второй параметр – количество нитей в блоке. Блок является логическим представлением мультипроцессора. В блоке исполняются нити, все нити делятся по варпам, каждый блок привязан к одному мультипроцессору, не может его менять и использует ресурсы мультипроцессора к которому привязан. Максимальный размер блока равен 1024 нити. Т.е. блок – группа нитей (не более 1024), использующих ресурсы конкретного физического мультипроцессора. Сетка блоков – логическое представление кластера мультипроцессоров, блоки никак друг от друга не зависят. Максимальное количество блоков намного больше чем количество мультипроцессоров на GPU. Каждый мультипроцессор одновременно может обрабатывать больше одного блока. Если мультипроцессоров не хватает для обработки всех блоков, блоки выстраиваются в очередь и ждут пока какой нибудь мультипроцессор освободится.
В примере функция-ядро запускается на одном блоке, который состоит из одной нити. Если вызывать её с параметрами <<<2,3>>>, функция-ядро выполнится 6 раз - отработают два блока по три нити, и строка "Hello, World" выведется 6 раз.
Функция cudaDeviceSynchronize – функция синхронизации. Код исполняющийся на GPU и CPU исполняется асинхронно, т.е. после вызова функции-ядра на хосте центральный процессор продолжает исполнять последовательный код не ожидая завершения вычислений на GPU. Чтобы синхронизировать вычисления производящиеся на GPU и CPU используется функция cudaDeviceSynchronize(). В точке вызова этой функции CPU будет ожидать пока закончатся все вычисления запущенные на GPU.
Блоки внутри сетки блоков и нити внутри блока могут индексироваться по одному, двум или трём измерениям. Т.е. при запуске функции ядра указывается не общий размер блока и сетки блоков, а размер каждого измерения. В примере выше индексация происходит по одному измерению (размеры второго и третьего неявно установлены в 1). Обобщённый синтаксис функции-ядра выглядит следующим образом kernel<<<dim3 gridDim, dim3 blockDim>>> (param). dim3 - тип данных введённый в CUDA, который представляет собой вектор из трёх целочисленных значений. Вызов функции-ядра из примера kernel<<<1,1>>>() или kernel<<<2,3>>>() аналогичен вызовам kernel<<<dim3(1,1,1), dim3(1,1,1)>>>() и kernel<<<dim3(2,1,1), dim3(3,1,1)>>>() соответственно. На рисунках 4 и 5 показаны примеры представления различных способов индексации нитей и блоков. 
Введение такого синтаксиса руководствуется исключительно соображениями удобства написания кода и ничем больше.

Рис 4 – пример одномерной индексации нитей и блоков

Рис 5 – пример двумерной индексации нитей и блоков
[bookmark: header-n32]4. Алгоритм сложения двух векторов на GPU
Общая схема распараллеливания задач для вычислений на GPU ничем не отличается от распараллеливания задач для вычислений с использованием MPI - нужно разбить исходную задачу на множество подзадач, результат решения которых не зависит от результата друг друга. Простейшим примером такой задачи является алгоритм сложения двух векторов.

Рис. 6 – обобщённая схема сложения двух векторов
Последовательная версия алгоритма сложения двух векторов:
#include <stdlib.h>
#define N 100000

int main () {
	int *a = (int*)malloc(sizeof(int) * N);
	int *b = (int*)malloc(sizeof(int) * N);
	int *c = (int*)malloc(sizeof(int) * N);

	for(int i = 0; i < N; ++i) {
		a[i] = 1;
		b[i] = 1;
	}
	
	for(int i = 0; i < N; ++i) {
		c[i] = a[i] + b[i];
	}
	return 0;

}
 [image: D:\docs\cuda\new cuda\Serial Vector Add.png]Рис. 7 – последовательная схема вычисления суммы двух векторов
Проанализировав последовательный алгоритм можно увидеть, что вычисление каждого элемента c[i] не зависит от других значений вектора c. Исходя из этого можно сделать вывод, что вычислять значения c[i] можно параллельно. Т.е. нужно сделать так чтобы каждое значение c[i] вычислялось в отдельной нити.

Рис. 8 – параллельная схема сложения двух векторов
Для того чтобы дать указание какой-либо конкретной нити, нужно знать её номер. Для этого в CUDA API есть встроенные переменные threadIdx, blockIdx, blockDim, gridDim. Они представляют собой структуры с тремя целочисленными полями x, y, z - измерения индексации. threadIdx – номер нити внутри блока. blockIdx – номер блока внутри сетки. blockDim – размер блока. gridDim – размер сетки. 
[image: D:\docs\cuda\new cuda\threadperblocks.png]
Рис. 9 – схема обращения нитей блоков к элементам вектора
Вычислить глобальный номер нити в сетке можно получить, умножив номер блока на размер блока и прибавив к результату номер нити в блоке – threadIdx.x + blockIdx.x * blockDim.x (пример для одномерной индексации нитей и блоков). Глобальный номер нити можно использовать в качестве индекса векторов, т.е. нить с определённым номером будет обращаться к элементам векторов под этим же номером. Сложив элементы векторов, к которым есть доступ у нити получится один элемент результирующего вектора. После того как все нити закончат свои вычисления, будут вычислены все значения результирующего вектора.
[image: D:\docs\cuda\new cuda\globalindexthread.png]
Рис. 10 – Схема преобразования номеров нитей блоков в глобальные номера нитей (M – размер блока)
Кроме самого алгоритма нужно выполнить копирование данных с хоста на устройство для проведения вычислений и с устройства на хост результата вычислений для дальнейшей обработки. Для этого в CUDA API есть следующие функции:
__host__  __device__ cudaError_t cudaMalloc ( void** devPtr, size_t size ) – выделяет память на устройстве, где параметр devPtr – указатель куда будет помещён адрес выделенной памяти, size – размер выделяемой памяти в байтах. Функция может вызываться на хосте и из функций-ядер. 
 __host__ cudaError_t cudaMemcpy ( void* dst, const void* src, size_t count, cudaMemcpyKind kind ) – копирует данные между хостом и устройством. Параметр dst – адрес получателя данных, src – адрес источника данных, count – размер данных в байтах, kind – направление копирования, может принимать значения cudaMemcpyHostToHost (направление Host->Host), cudaMemcpyHostToDevice (Host->Device), cudaMemcpyDeviceToHost (Device->Host), cudaMemcpyDeviceToDevice (Device->Device), cudaMemcpyDefault – направление зависит от того, где выделена память источника и память получателя (требуется поддержка UVA). 
__host__  __device__ cudaError_t cudaFree ( void* devPtr ) – высвобождает память выделенную на устройстве. Параметр devPtr – адрес высвобождаемой памяти.
Т.е. общая схема вычислений выглядит следующим образом:
[image: D:\docs\cuda\new cuda\CpyToDevice.png]
Рис. 11 – копирование данных на устройство
[image: D:\docs\cuda\new cuda\Execute Code.png]
Рис. 12 – вычисления на устройстве
[image: D:\docs\cuda\new cuda\CpyToHost.png]
Рис. 13 – копирование результата на хост
Параллельная версия алгоритма сложения двух векторов:
#include <stdlib.h>
#define N 100000

__global__ void kernel (int *a, int *b, int *c) {
	int i = threadIdx.x + blockIdx.x * blockDim.x;
	if(i < N) {
		c[i] = a[i] + b[i];
	}

}

int main () {
	//Выделение памяти на хосте
	int *ha = (int*)malloc(sizeof(int) * N);
	int *hb = (int*)malloc(sizeof(int) * N);
	int *hc = (int*)malloc(sizeof(int) * N);

	for(int i = 0; i < N; ++i) {
		a[i] = 1;
		b[i] = 1;
	}
	
	int *dc;
	int *da;
	int* db;
	
	//Выделение памяти на устройстве
	cudaMalloc((void**) &da, sizeof(int) * N);
	cudaMalloc((void**) &db, sizeof(int) * N);
	cudaMalloc((void**) &dc, sizeof(int) * N);
	
	//Копирование исходных данных с хоста на устройство
	cudaMemcpy(da, ha, sizeof(int) * N, cudaMemcpyHostToDevice);
	cudaMemcpy(db, hb, sizeof(int) * N, cudaMemcpyHostToDevice);
	
	//Выставляем размер блока = 128 нитей
	int blockSize = 128;
	//Динамически высчитываем сколько блоков понадобится для вычислений
	int gridSize = N / blockSize + 1;
	
	kernel<<<gridSize, blockSize>>>(ad, db, dc);
	cudaDeviceSynchronize();
	
	//Копирование результата с устройства на хост
	cudaMemcpy(hc, dc, sizeof(int) * N, cudaMemcpyDeviceToHost);
	
	//Осовбождение памяти выделенной на устройстве
	cudaFree(da);
	cudaFree(db);
	cudaFree(dc);
	
	return 0;

}
[bookmark: header-n55]Контрольные вопросы
1. Что такое нить, блок, сетка блоков, варп, функция-ядро?
1. Что такое хост и устройство?
1. Как запустить функцию-ядро?
1. Как выделить память на устройстве?
1. Как скопировать данные на устройство с хоста? с устройства на хост?
1. Как выглядит общая схема вычислений с использованием GPU?
1. Как вычислить глобальный номер нити?
1. Реализуйте параллельный и последовательный варианты алгоритма приведения символов к одному регистру (верхний или нижний).
1. Проверьте реализованные алгоритмы на строках с длинами от 2^10 до 2^23.
[bookmark: header-n75]5. События, обработка ошибок и получение информации об устройстве
CUDA API предоставляет набор функций для записи событий в любой части программы и набор функций для обработки ошибок. Для событий был введён новый тип данных cudaEvent_t, а для ошибок cudaError_t. Все функции CUDA API кроме функций-ядер возвращают объект типа cudaError_t. Функции-ядра помеченные спецификаторами __host__ или __device__ возвращают значения типа указанного при определении функции. Функции-ядра помеченные спецификатором __device__ всегда имеют тип данных void.
__host__ cudaError_t cudaEventCreate ( cudaEvent_t* event ) – создание объекта события. Параметр event – адрес объекта события.
__host__  __device__ cudaError_t cudaEventDestroy ( cudaEvent_t event ) – удаление объекта события. Параметр event – объект события.
__host__  __device__ cudaError_t cudaEventRecord ( cudaEvent_t event, cudaStream_t stream = 0 ) – запись события. Вызов этой функции говорит о том, что в точке её вызова разработчик подразумевает, что произошло какое-то событие. Параметр event – объект события. Параметр stream – номер потока, по умолчанию он равен нулю. Подробнее про потоки будет рассказано ниже, а пока этот параметр можно игнорировать.
__host__ cudaError_t cudaEventSynchronize ( cudaEvent_t event ) – ожидание завершения всех асинхронных команд (синхронизация). Параметр event – объект события.
__host__ cudaError_t cudaEventElapsedTime ( float* ms, cudaEvent_t start, cudaEvent_t end ) – расчёт времени прошедшего между событиями start и stop. Параметры start и stop – объекты событий, событие start должно произойти раньше для корректного расчёта. Параметр ms – адрес по которому будет записано время в миллисекундах.
char* cudaGetErrorString(cudaError_t error) – возвращает описание ошибки по её числовому коду. Параметр error – код ошибки.
cudaError_t cudaGetLastError() – возвращает код последней произошедшей ошибки. Когда при вызове функции CUDA API или функции-ядра возникает ошибка, её код записывается в специальную глобальную переменную. Эта функция основной способ получения кода ошибки, возникшей в функции-ядре.
Параллельный алгоритм сложения двух векторов с измерением времени выполнения операций и обработкой ошибок:
#include <stdlib.h>
#include <stdio.h>
#define N 100000

__global__ void kernel (int *a, int *b, int *c) {
	int i = threadIdx.x + blockIdx.x * blockDim.x;
	if(i < N) {
		c[i] = a[i] + b[i];
	}

}

int main () {
	//Выделение памяти на хосте
	int *ha = (int*)malloc(sizeof(int) * N);
	int *hb = (int*)malloc(sizeof(int) * N);
	int *hc = (int*)malloc(sizeof(int) * N);

	for(int i = 0; i < N; ++i) {
		ha[i] = 1;
		hb[i] = 1;
	}
	
	int *dc;
	int *da;
	int* db;
	
	//Выделение памяти на устройстве
	printf("Malloc da - %s\n", cudaGetErrorString( cudaMalloc((void**) &da, sizeof(int) * N) ));
	printf("Malloc db - %s\n", cudaGetErrorString( cudaMalloc((void**) &db, sizeof(int) * N) ));
	printf("Malloc dc - %s\n", cudaGetErrorString( cudaMalloc((void**) &dc, sizeof(int) * N) ));

	//Создание и инициализация объектов событий	
	cudaEvent_t start, stop;
	printf("Create event start - %s\n", cudaGetErrorString( cudaEventCreate(&start) ));
	printf("Create event stop - %s\n", cudaGetErrorString( cudaEventCreate(&stop) ));
	
	//Точка программы в которой произошло событие start
	printf("Event start record - %s\n", cudaGetErrorString( cudaEventRecord(start,0) ));

	//Копирование исходных данных с хоста на устройство
	printf("Copy ha to da - %s\n", cudaGetErrorString( cudaMemcpy(da, ha, sizeof(int) * N, cudaMemcpyHostToDevice) ));
	printf("Copy hb to db - %s\n", cudaGetErrorString( cudaMemcpy(db, hb, sizeof(int) * N, cudaMemcpyHostToDevice) ));
	
	//Выставляем размер блока = 128 нитей
	int blockSize = 128;
	//Динамически высчитываем сколько блоков понадобится для вычислений
	int gridSize = N / blockSize + 1;
	
	kernel<<<gridSize, blockSize>>>(da, db, dc);
	printf("Kernel launch - %s\n", cudaGetErrorString( cudaGetLastError() ));
	//Копирование результата с устройства на хост
	printf("Copy dc to hc - %s\n", cudaGetErrorString( cudaMemcpy(hc, dc, sizeof(int) * N, cudaMemcpyDeviceToHost) ));

	//Точка в программе в которой произошло событие stop
	printf("Record stop event - %s\n", cudaGetErrorString( cudaEventRecord(stop,0) ));
	//Ожидание завершения всех асинхронных операций
	printf("Synchronize - %s\n", cudaGetErrorString( cudaEventSynchronize(stop) ));

	//Расчёт прошедшего времени между событиями start и stop
	float elapsedTime;
	printf("Elapsed time - %s\n", cudaGetErrorString( cudaEventElapsedTime(&elapsedTime, start, stop) ));

	//Уничтожение объектов событий  
	printf("Destroy start event - %s\n", cudaGetErrorString( cudaEventDestroy(start) ));
	printf("Destroy stop event - %s\n", cudaGetErrorString( cudaEventDestroy(stop) ));
	
	printf("Elapsed time = %f\n", elapsedTime);
	//Осовбождение памяти выделенной на устройстве
	printf("Free da - %s\n", cudaGetErrorString( cudaFree(da) ));
	printf("Free db - %s\n", cudaGetErrorString( cudaFree(db) ));
	printf("Free dc - %s\n", cudaGetErrorString( cudaFree(dc) ));
	
	return 0;

}
Вывод программы:
Malloc da - no error
Malloc db - no error
Malloc dc - no error
Create event start - no error
Create event stop - no error
Event start record - no error
Copy ha to da - no error
Copy hb to db - no error
Kernel launch - no error
Copy dc to hc - no error
Record stop event - no error
Synchronize - no error
Elapsed time - no error
Destroy start event - no error
Destroy stop event - no error
Elapsed time = 0.413984
Free da - no error
Free db - no error
Free dc - no error
Вывод программы, если поменять размер блока со 128 на 1280:
Malloc da - no error
Malloc db - no error
Malloc dc - no error
Create event start - no error
Create event stop - no error
Event start record - no error
Copy ha to da - no error
Copy hb to db - no error
Kernel launch - invalid configuration argument
Copy dc to hc - no error
Record stop event - no error
Synchronize - no error
Elapsed time - no error
Destroy start event - no error
Destroy stop event - no error
Elapsed time = 0.327296
Free da - no error
Free db - no error
Free dc - no error
Программа сигнализирует, что параметры запуска функции-ядра некорректны. Это произошло потому что размер блока не должен превышать 1024 нити.
cudaError_t cudaGetDevicePropertis (cudaDeviceProp* props, int deviceNo) – получение информации об устройстве. Параметр props – адрес на структуру куда будет записана информация об устройстве. Параметр deviceNo – номер устройства. Устройства нумеруются с нуля. Структура cudaDeviceProp содержит большое количество информации об устройстве такой как максимальное количество регистров на блок, максимальный размер разделяемой памяти на блок, уникальный идентификатор устройства (uuid), может ли устройство исполнять несколько функций-ядер параллельно и т.д. Подробнее о всех полях структуры cudaDeviceProp можно узнать из официальной документации Nvidia
[bookmark: header-n92]Контрольные вопросы
1. Как измерить время вычислений проводимых на GPU?
1. Какие функции в CUDA API существуют для обработки ошибок?
1. Добавьте обработку ошибок в алгоритмы, реализованные в предыдущей главе и измерения времени выполнения при помощи событий.
1. Сравните время выполнения последовательного и параллельного алгоритмов с длинами строк от 2^10 до 2^23. Замеры времени для алгоритма, исполняющегося на GPU, всегда нужно проводить включая пересылки памяти между хостом и устройством

[bookmark: header-n103]6. Профилирование программ
В комплект поставки Nvidia CUDA Tollkit входят графический профилировщик программ Nvidia Visual Profiler и консольный профилировщик программ nvprof.
Утилита nvprof позволяет собирать информацию о активностях как на GPU так и на CPU включая исполнение функций-ядер, копирование данных, вызовы CUDA API, информацию о событиях, метрики функций-ядер, например пропускную способность памяти. Результаты отображаются сразу в консоли, но могут быть сохранены или импортированы в Visual Profiler.
Из командной строки синтаксис вызова утилиты nvprof выглядит следующим образом:
nvprof [options] [application] [application-arguments]
Где options параметры профилировщика, application – приложение для которого будет собираться статистика, application-arguments – параметры принимаемые application.
nvprof имеет несколько режимов работы: сводный режим, GPU-trace, API-trace, сводный режим + события и метрики, trace-mode + события и метрики.
[bookmark: header-n110]6.1. Сводный режим
Сводный режим – режим работы по умолчанию. В этом режиме профилировщик выводит общее время работы функции-ядра на устройстве, количество вызовов функции-ядра, время, затраченное на копирование памяти (каждое направление копирования учитывается отдельно), сводку всех вызовов CUDA API.
Пример работы nvprof в сводном режиме (число 27694 – номер профилируемого процесса):
==27694== Profiling result:
Time(%)      Time     Calls       Avg       Min       Max  Name
 99.94%  1.11524s       301  3.7051ms  3.6928ms  3.7174ms  void matrixMulCUDA<int=32>(float*, float*, float*, int, int)
  0.04%  406.30us         2  203.15us  136.13us  270.18us  [CUDA memcpy HtoD]
  0.02%  248.29us         1  248.29us  248.29us  248.29us  [CUDA memcpy DtoH]

==27964== API calls:
Time(%)      Time     Calls       Avg       Min       Max  Name
 49.81%  285.17ms         3  95.055ms  153.32us  284.86ms  cudaMalloc
 25.95%  148.57ms         1  148.57ms  148.57ms  148.57ms  cudaEventSynchronize
 22.23%  127.28ms         1  127.28ms  127.28ms  127.28ms  cudaDeviceReset
  1.33%  7.6314ms       301  25.353us  23.551us  143.98us  cudaLaunch
  0.25%  1.4343ms         3  478.09us  155.84us  984.38us  cudaMemcpy
  0.11%  601.45us         1  601.45us  601.45us  601.45us  cudaDeviceSynchronize
  0.10%  564.48us      1505     375ns     313ns  3.6790us  cudaSetupArgument
  0.09%  490.44us        76  6.4530us     307ns  221.93us  cuDeviceGetAttribute
  0.07%  406.61us         3  135.54us  115.07us  169.99us  cudaFree
  0.02%  143.00us       301     475ns     431ns  2.4370us  cudaConfigureCall
  0.01%  42.321us         1  42.321us  42.321us  42.321us  cuDeviceTotalMem
  0.01%  33.655us         1  33.655us  33.655us  33.655us  cudaGetDeviceProperties
  0.01%  31.900us         1  31.900us  31.900us  31.900us  cuDeviceGetName
  0.00%  21.874us         2  10.937us  8.5850us  13.289us  cudaEventRecord
  0.00%  16.513us         2  8.2560us  2.6240us  13.889us  cudaEventCreate
  0.00%  13.091us         1  13.091us  13.091us  13.091us  cudaEventElapsedTime
  0.00%  8.1410us         1  8.1410us  8.1410us  8.1410us  cudaGetDevice
  0.00%  2.6290us         2  1.3140us     509ns  2.1200us  cuDeviceGetCount
  0.00%  1.9970us         2     998ns     520ns  1.4770us  cuDeviceGet
Сводку вызовов CUDA API можно отключить добавив опцию --profile-api-trace none при запуске профилировщика. Если расчёты производятся на нескольких GPU можно получить информацию для отдельно для каждого GPU добавив опцию --pront-summary-per-gpu.
[bookmark: header-n115]6.2. GPU-trace и API-trace
Режимы GPU-trace и API-trace могут использоваться как вместе, так и по отдельности. GPU-trace выводит все действия выполненные на GPU в хронологическом порядке. Для каждой функции-ядра выводятся параметры используемой памяти (сколько выделено, пропускная способность и т.д.). Чтобы вызвать nvprof в режиме GPU-trace нужно во время вызова утилиты добавить опцию --print-gpu-trace.
Пример вывода профилировщика в режиме GPU-trace (для читабельности таблица разбита на две части - левую и правую):
 	Start  Duration            Grid Size      Block Size     Regs*    SSMem*
 133.81ms  135.78us                    -               -         -         -
 134.62ms  270.66us                    -               -         -         -
 134.90ms  3.7037ms            (20 10 1)       (32 32 1)        29  8.1920KB
 138.71ms  3.7011ms            (20 10 1)       (32 32 1)        29  8.1920KB
 1.24341s  3.7011ms            (20 10 1)       (32 32 1)        29  8.1920KB
 1.24711s  3.7046ms            (20 10 1)       (32 32 1)        29  8.1920KB
 1.25089s  248.13us                    -               -         -         -
DSMem*      Size  Throughput           Device   Context    Stream  Name
	-  409.60KB  3.0167GB/s  GeForce GT 640M         1         2  [CUDA memcpy HtoD]
	-  819.20KB  3.0267GB/s  GeForce GT 640M         1         2  [CUDA memcpy HtoD]
	0B        -           -  GeForce GT 640M         1         2  void matrixMulCUDA<int=32>(float*, float*, float*, int, int) [94]
	0B        -           -  GeForce GT 640M         1         2  void matrixMulCUDA<int=32>(float*, float*, float*, int, int) [105]
	0B        -           -  GeForce GT 640M         1         2  void matrixMulCUDA<int=32>(float*, float*, float*, int, int) [2191]
	0B        -           -  GeForce GT 640M         1         2  void matrixMulCUDA<int=32>(float*, float*, float*, int, int) [2198]
	-  819.20KB  3.3015GB/s  GeForce GT 640M         1         2  [CUDA memcpy DtoH]


Regs: Number of registers used per CUDA thread. This number includes registers used internally by the CUDA driver and/or tools and can be more than what the compiler shows.
SSMem: Static shared memory allocated per CUDA block.
DSMem: Dynamic shared memory allocated per CUDA block.
Режим API-trace показывает все вызовы CUDA API в хронологическом порядке. Для включения этого режима нужно добавить опцию --print-api-trace.
Пример вывода в режиме API-trace:
==27722== Profiling result:
   Start  Duration  Name
108.38ms  6.2130us  cuDeviceGetCount
108.42ms     840ns  cuDeviceGet
108.42ms  22.459us  cuDeviceGetName
108.45ms  11.782us  cuDeviceTotalMem
108.46ms     945ns  cuDeviceGetAttribute
149.37ms  23.737us  cudaLaunch (void matrixMulCUDA<int=32>(float*, float*, float*, int, int) [2198])
149.39ms  6.6290us  cudaEventRecord
149.40ms  1.10156s  cudaEventSynchronize
<...more output...>
1.25096s  21.543us  cudaEventElapsedTime
1.25103s  1.5462ms  cudaMemcpy
1.25467s  153.93us  cudaFree
1.25483s  75.373us  cudaFree
1.25491s  75.564us  cudaFree
1.25693s  10.901ms  cudaDeviceReset
[bookmark: header-n123]6.3. События и метрики
К двум предыдущим режимам можно добавить дополнительно опции для вывода информации о специфичных событиях и метриках. События и метрики можно указывать совместно. Чтобы задать одно или несколько событий нужно добавить при запуске nvprof опцию --events и после пробела перечислить события, для которых требуется собрать информацию. События перечисляются через запятую без пробелов. Чтобы задать одну или несколько метрик нужно добавить при запуске nvprof опцию --metrics и после пробела перечислить метрики, для которых требуется собрать информацию. Метрики перечисляются через запятую без пробелов. Если требуется собрать информацию по всем событиям или метрикам можно воспользоваться опциями --events all и --metrics all для событий и метрик соответственно. Чтобы посмотреть список всех доступных событий или метрик нужно запустить профилировщик с опцией --query-events или --query-metrics для событий и метрик соответственно.
Пример запуска nvprof в сводном режиме с дополнительными метриками:
nvprof --metrics gst_efficiency,gld_efficiency,gld_throughput,gst_throughput,dram_read_throughput,dram_write_throughput,gld_requested_throughput,gst_requested_throughput,global_hit_rate,dram_utilization ./cpy0

threads per block = 1024
Elapsed time: 61.8226 ms

==8559== NVPROF is profiling process 8559, command: ./cpy0
==8559== Some kernel(s) will be replayed on device 0 in order to collect all events/metrics.
==8559== Profiling application: ./cpy0
==8559== Profiling result:
==8559== Metric result:
Invocations                               Metric Name         Min         Max         Avg
Device "GeForce GTX 1050 (0)"
    Kernel: kernel_copy(int*, int*)
          1                            gst_efficiency      82.04%      82.04%      82.04%
          1                            gld_efficiency      82.04%      82.04%      82.04%
          1                            gld_throughput  52.265GB/s  52.265GB/s  52.265GB/s
          1                            gst_throughput  52.265GB/s  52.265GB/s  52.265GB/s
          1                      dram_read_throughput  42.878GB/s  42.878GB/s  42.878GB/s
          1                     dram_write_throughput  42.915GB/s  42.915GB/s  42.915GB/s
          1                  gld_requested_throughput  42.876GB/s  42.876GB/s  42.876GB/s
          1                  gst_requested_throughput  42.876GB/s  42.876GB/s  42.876GB/s
          1                           global_hit_rate      48.70%      48.70%      48.70%
          1                          dram_utilization    High (9)    High (9)    High (9)
В примере используются метрики пропускной способности памяти.
[bookmark: header-n128]6.4. Полезные метрики
achieved_occupancy - процент заполняемости мультипроцессоров
branch_efficiency – доля варпов, выполненных без бранчей
warp_execution_efficiency – средняя доля активных нитей в варпах
inst_replay_overhead–повторы инструкций (из-за сериализации) / общее число выполненных устройством инструкций
shared_replay_overhead,global_cache_replay_overhead, local_replay_overhead–разделение предыдущего по причинам
dram_read_throughput–объем памяти, отданной ядру /  время выполнения
gld_throughput-объем глобальной памяти, отданной ядру /  время выполнения
gld_requested_throughput-объем глобальной памяти, запрошенный ядром /  время выполнения
gld_efficiency–gld_requested_throughput/ gld_throughput
dram_write_throughput, gst_throughput, gst_requested_throughput, gst_efficiency-аналогично для записи
l1_cache_global_hit_rate–доля кеш-попаданий при обращении к глобальной памяти
l1_cache_local_hit_rate–доля кеш-попаданий при обращении к локальной памяти
l2_l1_read_hit_rate–доля кеш попаданий при обращении кешаl1 к кешуl2
local_memory_overhead-доля локальной памяти в обменах между l1 и l2
IPC –число инструкций, запускаемых за цикл работы warp scheduler
[bookmark: header-n130]6.5. Контрольные вопросы
1. Зачем используется утилита nvprof?
1. В каких режимах работает утилита nvprof?
1. Как добавить к выводу утилиты nvprof добавить информацию о дополнительных событиях?
1. Как добавить к выводу утилиты nvprof добавить дополнительные метрики?
1. Как посмотреть все доступные события для утилиты nvprof?
1. Как посмотреть все доступные метрики для утилиты nvprof?
[bookmark: header-n144]7. Глобальная, локальная и константная память
[bookmark: header-n145]7.1. Глобальная память
Глобальная память (global memory) – основная, медленная по скорости доступа к данным память, расположенная в чипах DRAM устройства. Область видимости глобальной памяти – сетка блоков функции-ядра. Глобальную память можно выделить динамически с помощью функции cudaMalloc (как в примере со сложением двух векторов) или статически, объявив глобальную переменную со спецификатором __device__.
Пример выделения глобальной памяти динамически на хосте:
__global__ void kernel(int*arrayOnDevice) {
    arrayOnDevice[threaIdx.x] = threaIdx.x;
}
int main() {
    size_tsize = 0;
    void*devicePtr= NULL;
    int hostMem[512];
    cudaMalloc(&devicePtr, sizeof(hostMem));
    cudaMemcpy(devicePtr, hostMem, size, cudaMemcpyHostToDevice);
    kernel<<<1,512>>>(devicePtr);
}
Пример выделения глобальной памяти статически:
__device__ int arrayOnDevice[512]
__global__ void kernel() {
    arrayOnDevice[threaIdx.x] = threaIdx.x;
}

int main() {
    size_t size = 0;
    void *devicePtr = NULL;
    int hostMem[512];
    cudaGetSymbolSize(&size, arrayOnDevice);
    cudaMemcpyToSymbol(arrayOnDevice, hostMem, size);
    kernel<<<1,512>>>(devicePtr);
}
Функция __host__ cudaError_t cudaGetSymbolSize ( size_t* size, const T& symbol ) – определяет размер объекта переданного в качестве второго параметра. Параметр size – адрес по которому будет записан размер объекта symbol.
__host__ cudaError_t cudaMemcpyToSymbol ( const T& symbol, const void* src, size_t count, size_t offset = 0, cudaMemcpyKind kind = cudaMemcpyHostToDevice ) – копирует данные в объект symbol из источника src. Параметр count – размер копируемых данных. Параметр offset – смещение от начала symbol в байтах. kind – направление передачи данных, по умолчанию копирование идёт с хоста на устройство, но можно установить направление Device->Device.
Ещё один пример работы со статически выделенной глобальной памятью:
__device__ int arrayOnDevice[512];
__global__ void kernel() {
    arrayOnDevice[threaIdx.x] = threaIdx.x;
}
int main() {
    size_t size = 0;
    int hostMem[512];
    void *devicePtr = NULL;
    cudaGetSymbolSize(&size, arrayOnDevice);
    cudaGetSymbolAddress(&devicePtr, arrayOnDevice);
    cudaMemcpy(devicePtr, hostMem, size, cudaMemcpyHostToDevice);
    kernel<<<1,512>>>();
}
__host__ cudaError_t cudaGetSymbolAddress ( void** devPtr, const T& symbol ) – копирует в devPtr адрес объекта symbol. Если symbol не найден, значение devPtr остаётся неизменным.
Функции-ядра обращаются не напрямую к глобальной памяти, а в кэши L1 и L2. В кэш L1 данные загружаются по 128 байт, а в L2 по 32 байта. Т.е. даже если функция-ядро запросит один байт из глобальной памяти при включенном кэшировании в L1 кэш будет загружено 128 байт. Таким образом наибольшей производительности при работе с глобальной памятью можно добиться, если нити варпа будут работать с отрезком в 128 байт с началом кратным 128. Доступ к глобальной памяти при котором соблюдается это условие называется coalescing.
[image: D:\docs\cuda\new cuda\coalescing.png]
Рис 14 – пример coalescing'а
[image: D:\docs\cuda\new cuda\uncoalescing.png]
Рис 15 – пример uncoalescing доступа к глобальной памяти
Пример функции-ядра работающей с глобальной памятью отрезками по 128 байт:
__global__ void kernel_copy(int *a, int *c) {
        int i = threadIdx.x + blockDim.x * blockIdx.x;
        if(i < SIZE) {
                c[i] = a[i];
        }
}



Вывод nvprof:
Invocations                               Metric Name         Min         Max         Avg
Device "GeForce GTX 1050 (0)"
    Kernel: kernel_copy(int*, int*)
          1                            gst_efficiency      82.04%      82.04%      82.04%
          1                            gld_efficiency      82.04%      82.04%      82.04%
          1                            gld_throughput  52.265GB/s  52.265GB/s  52.265GB/s
          1                            gst_throughput  52.265GB/s  52.265GB/s  52.265GB/s
          1                      dram_read_throughput  42.878GB/s  42.878GB/s  42.878GB/s
          1                     dram_write_throughput  42.915GB/s  42.915GB/s  42.915GB/s
          1                  gld_requested_throughput  42.876GB/s  42.876GB/s  42.876GB/s
          1                  gst_requested_throughput  42.876GB/s  42.876GB/s  42.876GB/s
          1                           global_hit_rate      48.70%      48.70%      48.70%
          1                          dram_utilization    High (9)    High (9)    High (9)
При анализе профилировщиком использовались следующие метрики:
dram_utilization – уровень пропускной способности dram относительно пиковой пропускной способности (от 0 до 10).
dram_read_throughput – пропускная способность считывания из dram.
dram_write_throughput – пропускная способность записи в dram.
global_hit_rate – процент попаданий в L1/texture кэш.
gld_throughput – пропускная способность считывания из глобальной памяти
gld_reqested_throughput – эффективная пропускная способность считываний из глобальной памяти.
gld_efficiency – эффективность считываний из глобальной памяти – отношение эффективной пропускной способности считываний из глобальной памяти к общей пропускной способности считываний из глобальной памяти.
gst_throughput – пропускная способность записи в глобальную память.
gst_requested_throughput – эффективная пропускная способность записи в глобальную память.
gst_efficiency – эффективность записи в глобальную – отношение gst_requested_throughput к gst_throughput.



Пример функции-ядра, работающего с разбросанными по глобальной памяти данными:
__global__ void kernel_copy(int *a, int *b) {
        int i = threadIdx.x + blockDim.x * blockIdx.x;
        if(i < SIZE) {
                i = (i * 18) % SIZE;
                c[i] = a[i];
        }
}
Вывод профилировщика:
Invocations                               Metric Name         Min         Max         Avg
Device "GeForce GTX 1050 (0)"
    Kernel: kernel_copy(int*, int*)
          1                            gst_efficiency      12.50%      12.50%      12.50%
          1                            gld_efficiency      12.50%      12.50%      12.50%
          1                            gld_throughput  41.174GB/s  41.174GB/s  41.174GB/s
          1                            gst_throughput  41.174GB/s  41.174GB/s  41.174GB/s
          1                      dram_read_throughput  41.979GB/s  41.979GB/s  41.979GB/s
          1                     dram_write_throughput  41.216GB/s  41.216GB/s  41.216GB/s
          1                  gld_requested_throughput  5.1467GB/s  5.1467GB/s  5.1467GB/s
          1                  gst_requested_throughput  5.1467GB/s  5.1467GB/s  5.1467GB/s
          1                           global_hit_rate       0.00%       0.00%       0.00%
          1                          dram_utilization    High (8)    High (8)    High (8)
Во втором случае заметно упала пропускная способность памяти – эффективность каждой транзакции, что дало существенное увеличение времени затраченного на выполнение функции-ядра 61 миллисекунда в первом случае против 84 миллисекунд во втором случае.
Если доступ к глобальной памяти по каким-то причинам оптимизировать не получается, можно отключить L1 кэширование добавив опции -Xptxas -dlcm=cg при компиляции программы. В этом случае при трансляции в бинарный код не будут использоваться инструкции L1 кэша.
[image: D:\docs\cuda\new cuda\L2cache.png]
Рис 16 – обращение к глобальной памяти с выключенным L1 кэшированием
[bookmark: header-n172]7.2. Многомерные массивы в глобальной памяти
Первое правило при работе с многомерными массивами в глобальной памяти – не использовать косвенную адресацию. В качестве примера возьмём двумерный массив A[i][j]. При доступе к данным в двумерном массиве требуется два обращения в глобальную память (A[i] и A[i][j]), что противоречит желанию снизить количество обращений к минимуму из-за низкой скорости доступа к данным. Если обращения к A[i] из разных нитей варпа скорее всего попадут в одну транзакцию, то второе обращение (A[i][j]) в одну транзакцию не попадут. Поэтому многомерные массивы следует обрабатывать как одномерные.
Пусть в глобальной памяти в линейном виде хранится матрица A с длиной строки в 120 элементов типа int (480 байт). Обращение к элементу матрицы – A[i*120 + j]. При построчной обработке элементов матрицы адреса запрашиваемых блоков глобальной памяти не будут кратны 128 байтам. Из-за этого каждое обращение варпа в память будет инициировать две транзакции из глобальной памяти. Для оптимизации доступа можно добавить в конце каждой строки неиспользуемую область памяти, чтобы размеры строк были кратны 128 байтам, что сократит количество транзакций.
Для выделения линейной области памяти под матрицы рекомендуется использовать функцию __host__ cudaError_t cudaMallocPitch ( void** devPtr, size_t* pitch, size_t width, size_t height ). Она выделяет минимум width (в байтах) * height (в байтах) байт линейной памяти и записывает её адрес в devPtr. Функция может выделить больше памяти для того чтобы гарантировать, что доступ к строкам был выровненным. Фактическая ширина строки в байтах записывается в переменную pitch. Адрес элемента расположенного в строке Row и столбце Column рассчитывается по формуле T* pElement = (T*)((char*)BaseAddress + Row * pitch) + Column;. Где T – тип данных элемента, а BaseAddress – адрес начала массива.
__host__ cudaError_t cudaMemcpy2D ( void* dst, size_t dpitch, const void* src, size_t spitch, size_t width, size_t height, cudaMemcpyKind kind ) – копирует матрицу из линейной области памяти src в линейную область памяти dst. Параметр dpitch – фактическая ширина строки получателя (в байтах). Параметр spitch – фактическая ширина строки источника (в байтах). Параметр width – сколько байт из строки источника нужно скопировать. Параметр height – количество строк которые будут скопированы. Параметр kind – направление копирования.
Для работы с трёхмерными массивами рекомендуется использовать функции cudaMalloc3D и cudaMemcpy3D. Для создания массивов make_cudaExtent или make_cudaPitchedPtr
Пример работы с двумерным массивом:
__global__ void MyKernel(float* devPtr, size_t pitch, int width, int height) {
    for (int r = 0; r < height; ++r) {
        float* row = (float*)((char*)devPtr + r * pitch); 
        for (int c = 0; c < width; ++c) { 
            float element = row[c]; 
        } 
    }
}

int main () {
    int width = 64, height = 64; 
    float* devPtr; 
    size_t pitch; 
    cudaMallocPitch(&devPtr, &pitch, width * sizeof(float), height); 
    MyKernel<<<100, 512>>>(devPtr, pitch, width, height); 
}
Пример работы с трёхмерным массивом:
__global__ void MyKernel(cudaPitchedPtr devPitchedPtr, int width, int height, int depth) 
{ 
    char* devPtr = devPitchedPtr.ptr; 
    size_t pitch = devPitchedPtr.pitch;
    size_t slicePitch = pitch * height; 
    for (int z = 0; z < depth; ++z) { 
        char* slice = devPtr + z * slicePitch; 
        for (int y = 0; y < height; ++y) { 
            float* row = (float*)(slice + y * pitch); 
            for (int x = 0; x < width; ++x) { 
                float element = row[x];
            } 
        } 
    }     
}

int main () {
    int width = 64, height = 64, depth = 64; 
    cudaExtent extent = make_cudaExtent(width * sizeof(float), height, depth);
    cudaPitchedPtr devPitchedPtr; 
    cudaMalloc3D(&devPitchedPtr, extent); 
    MyKernel<<<100, 512>>>(devPitchedPtr, width, height, depth); 
}
Если доступ к элементам матрицы осуществляется не построчно, а по столбцам, то в любом случае потребуется больше одной транзакции для доступа к данным. Если такой доступ происходит больше одного раза, то имеет смысл транспонировать матрицу или если есть возможность изначально хранить её в транспонированном виде.
[bookmark: header-n183]7.3. Массивы структур и структуры массивов в глобальной памяти (AOS vs. SOA)
Пусть есть структура состоящая из трёх целочисленных полей:
struct example{
    int a;
    int b;
    int c;
}
И функция-ядро, обрабатывающая массив таких структур:
__global__ void kernel(example *arrayOfExamples) {
    int idx = threadIdx.x + blockIdx.x * blockDim.x;
    arrayOfExamples[idx].c = arrayOfExamples[idx].b + arrayOfExamples[idx].a;
}
При обращении нитей варпа за полями b будет совершено три транзакции, потому что в памяти эти поля расположены не рядом друг с другом, а на расстоянии в 8 байт (если не учитывать длину самого поля b).
[image: D:\docs\cuda\new cuda\AOS.png]Рис. 17 – AOS
Если расположить одинаковые поля в памяти рядом друг с другом (использовать не массив структур, а структуру массивов), можно добиться того, что при обращении нитей варпа за значениями из конкретного поля будет совершена всего одна транзакция.
struct example{
    int *a;
    int *b;
    int *c;}

__global__ void kernel(example arrayOfExamples) {
    int idx = threadIdx.x + blockIdx.x * blockDim.x;
    arrayOfExamples.c[idx] = arrayOfExamples.b[idx] + arrayOfExamples.a[idx];
}
[image: D:\docs\cuda\new cuda\SOA.png]Рис. 18 – SOA
[bookmark: header-n193]7.4. Локальная память
Локальная память – используется для хранения локальных переменных, когда не хватает регистров; скорость доступа низкая, так как расположена в микросхемах DRAM, находящихся вне кристалла. Выделяется отдельно для каждой нити.
[bookmark: header-n195]7.5. Константная память
Константная память – память, располагающаяся в микросхемах DRAM, снабжена специальным константным кэшем. Из-за агрессивной стратегии кэширования обладает в среднем высокой скоростью доступа сравнимой с доступом к данным в L1 кэше, не смотря на то, что фактически находится в глобальной памяти. Данные в константную память можно записать только на хосте, на устройстве разрешён доступ только для чтения. Использование на устройстве не отличается от использования обычной переменной. Используется для передачи неизменяемых значений на устройство.
Константную память можно выделить только статически, объявив глобальную переменную и указав для неё спецификатор __constant__. Например __constant__ float constData[256]. Для работы с константной памятью на хосте можно использовать функции cudaMemcpyToSymbol, cudaGetSymbolAddress, cudaGetSymbolSize, использовавшиеся ранее для работы с глобальной памятью.
[bookmark: header-n198]7.6. Контрольные вопросы
1. Какими свойствами обладает глобальная память?
1. Как выделить область памяти в глобальной памяти? Как скопировать туда данные с хоста? Как скопировать оттуда данные на хост?
1. Что такое coalescing?
1. Почему может падать пропускная способность доступа к глобальной памяти?
1. Что такое локальная память?
1. Что такое константная память?
1. Как скопировать данные с хоста в константную память?
1. Можно ли изменять данные в константной памяти на устройстве?
1. Реализуйте параллельный алгоритм обмена элементов массива между диапазоном (first1, last1) и (first2, last2). Количество элементов в диапазоне должно быть одинаково, иначе сигнализировать об ошибке.
[bookmark: header-n218]8. Разделяемая память
Разделяемая память (shared memory) – небольшая по объёму, но очень быстрая по скорости доступа к данным память, потому что расположена рядом с вычислительными мощностями мультипроцессора (on-chip). Является ресурсом мультипроцессора, т.е. у каждого SM своя разделяемая память. Следовательно область видимости данных в разделяемой памяти – блок. Вся разделяемая память разбита на 32 банка данных. Последовательно расположенные 32-х битные слова расположены в последовательных банках памяти. Пропускная способность каждого банка 32 бита за два такта. Если одновременно идёт обращение к разным 32-х битным словам одного банка, возникает конфликт банков, степень которого определяется количеством различных 32-х битных слов к которым обращаются. Все конфликтные обращения обрабатываются последовательно, но если несколько или все нити варпа обращаются к одному и тому же 32-х байтовому слову конфликта не возникает. Если идёт обращение всех нитей такая ситуация называется broadcast, если обращаются несколько нитей – multicast.
[image: D:\docs\cuda\new cuda\Bank conflict.png]Рис. 18 – распределение 32-х битных слов по банкам данных
Выделить разделяемую память можно двумя способами – статически и динамически. Чтобы выделить разделяемую память статически нужно определить переменную на устройстве со спецификатором __shared__. Например:
__global__ void kernel() {
    __shared__ int val;
    __shared__ int arr[128];
    val = 6;
    for(int i = 0; i < 128; ++i) {
        arr[i] = i;
    }
}
Использование разделяемой памяти ничем не отличается от использования обычных переменных, но нельзя присвоить значение переменной со спецификатором __shared__ в момент объявления, только после этого (__shared__ int val = 0 – будет ошибкой).
Чтобы выделить разделяемую память динамически нужно объявить на устройстве указатель на разделяемую память со спецификатором extern, например extern __shared__ int array[] и при вызове функции-ядра указать третьим необязательным параметром сколько байт памяти нужно выделить на блок. Например:
#define N 100

__global__ void kernel() {
    extern __shared__ int array[];
    extern __shared__ int array2[];
    //Т.к. разделяемая память динамически выделется сразу на блок
    //для нескольких массивов её нужно распеределить вручную
    array2 = &(array[10]);
    for(int i = 0; i < 10; ++i) {
        array[i] = i;
    }
    
    for(int i = 0; i < N - 10; ++i) {
        array2[i] = i;
    }
}

int main () {
    kernel<<<5, 128, N * sizeof(int)>>>();
    return 0;
}
Обобщённая схема работы с разделяемой памятью выглядит следующим образом: копирование данных с хоста в глобальную память устройства -> копирование из глобальной памяти в разделяемую -> расчёты -> копирование результата в глобальную память -> копирование результата на хост. И т.к. разделяемая память намного меньшего объёма чем глобальная память часть копирование из глобальной памяти в разделяемую -> расчёты -> копирование результата в глобальную память происходит итеративно. Часть входных данных загружается в разделяемую память, над ней выполняются операции, результат копируется в глобальную память и в разделяемую память загружается следующая порция данных. В связи с этим возникает потребность в синхронизации нитей, работающих с разделяемой памятью (например, нужно быть уверенным, что все необходимые данные загрузились или все нити закончили работу с разделяемой памятью перед загрузкой новой порции данных в неё). Для этого используется функция __synchthreads() – барьерная синхронизация нитей блока. Нити блока будут ожидать в этой точке завершения работы других нитей блока.




Пример, демонстрирующий влияние конфликтов банков памяти:
#define MEMORY_SIZE 4096

using Type = uint32_t;

__global__ void kernel(int offset)
{
    __shared__ Type sharedMem[MEMORY_SIZE];

    int threadId = threadIdx.x;

    // Инициализация разделяемой памяти
    if (threadId == 0)
    {
        for (int i = 0; i < MEMORY_SIZE; i++) sharedMem[i] = 0;
    }
    __syncthreads();

    // Запись в разделяемую память, offset - смещение доступа
    //к разделяемой памяти (в 4-х байтных словах)
    uint32_t index = threadId * offset;
    for (int i = 0; i < 10000; i++)
    {
        sharedMem[index] += index * i;
        index += 32;
        index %= MEMORY_SIZE;
    }
}
Вывод nvprof для offset = 1 (нити варпа считывают данные последовательно без смещения):
Invocations            Metric Name                       Min         Max         Avg
1000                   shared_ld_bank_conflict           0           0           0  
1000                   shared_st_bank_conflict           0           0           0  
1000                         shared_efficiency           95.74%      95.74%      95.74%
1000      shared_load_transactions_per_request           1.000000    1.000000    1.000000
Вывод nvprof для offset = 32 (конфликт банков данных 32-й степени):
Invocations            Metric Name                  Min         Max         Avg
1000                   shared_ld_bank_conflict      310000      310000      310000
1000                   shared_st_bank_conflict      310000      310000      310000
1000                         shared_efficiency      3.14%       3.14%       3.14%
1000      shared_load_transactions_per_request      32.000000   32.000000   32.000000
Для профилирования использовались события: shared_ld_bank_conflict – количество конфликтов банков памяти при считывании данных, shared_st_bank_conflict– количество конфликтов банков памяти при записи данных. Метрики: shared_efficiency – эффективность использования пропускной способности шины данных разделяемой памяти, shared_load_transactions_per_request – количество транзакций при каждом запросе к разделяемой памяти.
[bookmark: header-n234]Контрольные вопросы
1. Что такое разделяемая память?
1. Что такое банк памяти?
1. Что такое конфликт банков памяти? Как избавиться от конфликтов банков памяти?
1. Как выделить разделяемую память?
1. Как скопировать туда данные с хоста?
1. В каких случаях использование разделяемой памяти повышает эффективность вычислений?
[bookmark: header-n248]9. Pinned memory (page-locked memory, закреплённая память)
По умолчанию вся память на хосте является подкачиваемой (pageble). При копировании данных с хоста на устройство CUDA Driver выделяет pinned memory на хосте и перемещает туда данные, только после этого перемещает данные из pinned memory в память устройство. Процесс можно оптимизировать, выделив pinned memory заранее, убрав одну пересылку данных на хосте.
Для работы с pinned memory есть следующие функции:
__host__ cudaError_t cudaMallocHost ( void** ptr, size_t size ) – выделяет page-locked memory размером size байт, адрес выделенной памяти возвращает в ptr.
__host__ cudaError_t cudaHostAlloc ( void** pHost, size_t size, unsigned int  flags ) – выделяет page-locked memory размером size байт, адрес выделенной памяти записывается в pHost, flags – флаги свойств выделяемой памяти. Флаги могут быть следующими: cudaHostAllocDefault – выделение памяти без специфичных свойств, вызов cudaHostAlloc будет аналогичен вызову cudaMallocHost. cudaHostAllocPortable – выделенная память может использоваться всеми GPU в системе. cudaHostAllocMapped – память отображается в адресное пространство устройства. cudaHostAllocWriteCombined – выделяет write-combined память, некэшируемую память, данные из которой могут быстрее передаваться по шине PCI Express. Характеризуется высокой скоростью записи в неё и низкой скоростью чтения из неё с хоста, хорошо подходит для передач данных в направлении хост -> устройство.
__host__ cudaError_t cudaHostRegister ( void* ptr, size_t size, unsigned int  flags ) – резервирует ранее уже выделенную память размером size байт, находящуюся по адресу ptr, как page-locked. Параметр flags аналогичен этому параметру в функции cudaHostAlloc.
__host__ cudaError_t cudaFreeHost ( void* ptr ) – высвобождает pinned memory по адресу ptr.
Сравнение скорости передачи данных с хоста на устройство и с устройства на хост разных типов памяти (pageble и pinned):
//Функция выводит время копирования данных с хоста на устройство и наоборот
void profileCopies(float        *h_a, 
                   float        *h_b, 
                   float        *d, 
                   unsigned int  n,
                   char         *desc)
{
  printf("\n%s transfers\n", desc);

  unsigned int bytes = n * sizeof(float);
    
  cudaEvent_t startEvent, stopEvent; 
  cudaEventCreate(&startEvent);
  cudaEventCreate(&stopEvent);

  //Замер времени копирования с хоста на устройство
  cudaEventRecord(startEvent, 0);
  cudaMemcpy(d, h_a, bytes, cudaMemcpyHostToDevice);
  cudaEventRecord(stopEvent, 0);
  cudaEventSynchronize(stopEvent);

  float time;
  cudaEventElapsedTime(&time, startEvent, stopEvent);
  printf("  Host to Device bandwidth (GB/s): %f\n", bytes * 1e-6 / time);
    
  //Замер времени копирования с устройства на хост
  cudaEventRecord(startEvent, 0);
  cudaMemcpy(h_b, d, bytes, cudaMemcpyDeviceToHost);
  cudaEventRecord(stopEvent, 0);
  cudaEventSynchronize(stopEvent);

  cudaEventElapsedTime(&time, startEvent, stopEvent);
  printf("  Device to Host bandwidth (GB/s): %f\n", bytes * 1e-6 / time);

  for (int i = 0; i < n; ++i) {
    if (h_a[i] != h_b[i]) {
      printf("*** %s transfers failed ***\n", desc);
      break;
    }
  }

  cudaEventDestroy(startEvent);
  cudaEventDestroy(stopEvent);
}

int main()
{
  unsigned int nElements = 4*1024*1024;
  const unsigned int bytes = nElements * sizeof(float);

  // host arrays
  float *h_aPageable, *h_bPageable;   
  float *h_aPinned, *h_bPinned;

  // device array
  float *d_a;

  // allocate and initialize
  h_aPageable = (float*)malloc(bytes);                    // host pageable
  h_bPageable = (float*)malloc(bytes);                    // host pageable
  cudaMallocHost((void**)&h_aPinned, bytes);			  // host pinned
  cudaMallocHost((void**)&h_bPinned, bytes); 			  // host pinned
  cudaMalloc((void**)&d_a, bytes);				          // device

  for (int i = 0; i < nElements; ++i) h_aPageable[i] = i;      
  memcpy(h_aPinned, h_aPageable, bytes);
  memset(h_bPageable, 0, bytes);
  memset(h_bPinned, 0, bytes);

  printf("Transfer size (MB): %d\n", bytes / (1024 * 1024));

  // Замеры времени копирования
  profileCopies(h_aPageable, h_bPageable, d_a, nElements, "Pageable");
  profileCopies(h_aPinned, h_bPinned, d_a, nElements, "Pinned");

  printf("n");

  
  cudaFree(d_a);
  cudaFreeHost(h_aPinned);
  cudaFreeHost(h_bPinned);
  free(h_aPageable);
  free(h_bPageable);

  return 0;
}
Вывод:
Pageable transfers
  Host to Device bandwidth (GB/s): 5.368503
  Device to Host bandwidth (GB/s): 5.627219

Pinned transfers
  Host to Device bandwidth (GB/s): 6.186581
  Device to Host bandwidth (GB/s): 6.670246
[bookmark: header-n259]Контрольные вопросы
1. Что такое pageble memory?
1. Что такое pinned memory?
1. Как выделить pinned memory?
1. Почему используя pinned memory можно увеличить скорость пересылки данных?
1. Исследуйте скорость передачи данных с хоста на устройство и обратно для pageble memory и pinned memory.
[bookmark: header-n271]10. Потоки (streams) в CUDA
В CUDA потоком называются операции, выполняющиеся последовательно, но при этом операции, принадлежащие разным потокам, могут исполняться параллельно. Если не указано явно в каком потоке выполняются операции, то они по умолчанию выполняются в нулевом потоке.
В CUDA следующие действия считаются независимыми и могут выполняться параллельно друг с другом: вычисления на хосте, вычисления на устройстве, копирование данных с хоста на устройство, копирование данных с устройства на хост, копирование данных в пределах устройства, копирование данных между устройствами.
Операции запуска функции-ядра, копирование данных в пределах устройства, копирование данных с хоста на устройство объёмом меньше чем 64 КБ, копирование данных при помощи функций с суффиксом Async. Т.е. вызов этих операций не блокирует исполнение команд на хосте.
Две команды, находящихся в разных потоках, не могут выполняться параллельно, если выполняются следующие действия: выделение закреплённой памяти, копирование данных в пределах устройства, любая команда в потоке NULL.
Чаще всего потоки используются для асинхронной передачи данных с хоста на устройство и с устройства на хост.
[image: D:\docs\cuda\new cuda\cuda-stream-2.png]Рис. 19 – синхронизированное исполнение алгоритма и с использованием потоков
На рисунке 19 показано два сценария. Первый сценарий – последовательно выполняется копирование всех данных на устройство, затем исполняется функция-ядро, после этого выполняется копирование результата на хост. Часто возникает ситуация, что для части вычислений нет необходимости во всех исходных данных, например, того чтобы получить один результирующий элемент при умножении матриц не требуется использовать все элементы исходных матриц, нужны только конкретная строка и конкретный столбец. В таком случае имеет смысл разбить исходный алгоритм на части и передавать только нужную для вычислений часть данных и копировать на хост полученную часть результата. Второй сценарий на рисунке 19 показывает разбиение исходного алгоритма на 4 потока. Все входные данные поделились на четыре части, каждая часть копируется на устройство после того как скопируется предыдущая часть, но т.к. передача данных между хостом и устройством может выполняться параллельно с функцией-ядром, если они находятся в разных потоках, по окончанию копирования очередной порции данных на устройство функция-ядро заканчивает обработку предыдущей порции данных и может отправить часть ответа обратно на хост. За счёт этого можно получить существенное ускорение.
Для работы с потоками в CUDA добавлен тип данных cudaStream_t. Чтобы создать поток нужно вызвать функцию __host__ cudaError_t cudaStreamCreate ( cudaStream_t* pStream ), параметр pStream адрес по которому будет записан созданный объект. Для асинхронного копирования данных нужно вызвать функцию __host__  __device__ cudaError_t cudaMemcpyAsync ( void* dst, const void* src, size_t count, cudaMemcpyKind kind, cudaStream_t stream = 0 ) – копирует count байт из src в dst в направлении kind (cudaMemcpyHostToDevice или cudaMemcpyDeviceToHost) в потоке stream. Для удаления потока используется функция __host__  __device__ cudaError_t cudaStreamDestroy ( cudaStream_t stream ), где stream – объект потока. Чтобы указать в каком потоке выполняться функции-ядру нужно третьим (или четвёртым, если выделяется динамическая разделяемая память) передать объект потока в качестве параметра во время запуска.


Пример использования потоков:
// size - размер порции данных
cudaStream_t stream[2];
for (int i = 0; i < 2; ++i) {
    cudaStreamCreate(&stream[i]);
}
float* hostPtr;
cudaMallocHost(&hostPtr, 2 * size);

for (int i = 0; i < 2; ++i) {
    cudaMemcpyAsync(inputDevPtr + i * size, hostPtr + i * size,
                    size, cudaMemcpyHostToDevice, stream[i]);
    MyKernel <<<100, 512, 0, stream[i]>>>
          (outputDevPtr + i * size, inputDevPtr + i * size, size);
    cudaMemcpyAsync(hostPtr + i * size, outputDevPtr + i * size,
                    size, cudaMemcpyDeviceToHost, stream[i]);
}

for (int i = 0; i < 2; ++i) {
    cudaStreamDestroy(stream[i]);
}
Копирование данных при помощи cudaMemcpyAsync работает только с pinned memory.
__host__ cudaError_t cudaDeviceSynchronize() – ожидает завершения всех выполняющихся потоков.
__host__ cudaError_t cudaStreamSynchronize ( cudaStream_t stream ) – ожидает завершения потока stream.
__host__ cudaError_t cudaLaunchHostFunc ( cudaStream_t stream, cudaHostFn_t fn, void* userData ) – вставляет вызов функции хоста fn (callback) в поток stream. Параметр userData – параметры передаваемые в callback функцию.
Пример вызова calback функции:
void CUDART_CB MyCallback(cudaStream_t stream, cudaError_t status, void *data){
    printf("Inside callback %d\n", (size_t)data);
}
...
for (size_t i = 0; i < 2; ++i) {
    cudaMemcpyAsync(devPtrIn[i], hostPtr[i], size, cudaMemcpyHostToDevice, stream[i]);
    MyKernel<<<100, 512, 0, stream[i]>>>(devPtrOut[i], devPtrIn[i], size);
    cudaMemcpyAsync(hostPtr[i], devPtrOut[i], size, cudaMemcpyDeviceToHost, stream[i]);
    cudaLaunchHostFunc(stream[i], MyCallback, (void*)i);
}
В примере выше функция MyCallback будет вызываться после каждой передачи данных с устройства на хост. Если вызвать эту функцию не через cudaLaunchHostFunc, она выполнится асинхронно с потоками, т.е. результат её работы можно будет ожидать в любой момент времени без блокировки потоков.
[bookmark: header-n289]Контрольные вопросы
1. Что такое поток в CUDA?
1. За счёт чего достигается ускорение вычислений при использовании потоков?
1. Какие операции в двух потоках могут исполняться параллельно?
1. Когда операции в двух потоках не могут исполняться параллельно?
[bookmark: header-n299]11. Текстурная память
Текстурная память является особым образом выделенной областью глобальной памяти. Обращение к текстурной памяти производится с использованием текстурного кэша, расположенного в мультипроцессоре по этому скорость в общем случае сопоставима со скоростью доступа к данным из L1 кэша. Текстурная память так-же позволяет использовать адресацию с плавающей точкой (при этом применяется линейная или билинейная интерполяция). Область видимости текстурной памяти – сетка блоков, с устройства доступна только для чтения. Для использования текстурной памяти необходимо задать объявление текстуры как глобальной переменной, а потом связать её с требуемой областью глобальной памяти. Тип данных для переменной, находящейся в текстурной памяти имеет вид texture<DataType, Type, ReadMode>, где DataType – тип данных текстурного элемента, Type – тип текстуры, может принимать значения cudaTextureType1D (по умолчанию), cudaTextureType2D, cudaTextureType3D, cudaTextureType1DLayered, cudaTextureType2DLayered, cudaTextureType3DLayered для одномерных, двумерных, трёхмерных текстур, текстур со слоями. ReadMode – спецификатор режима чтения. По умолчанию принимает значение cudaReadModeElementType – считывает текстуру, как элемент определённого типа, можно поменять на значение cudaReadModeNormalizedFloat – считывает текстуру как нормализованное число с плавающей точкой.
Текстуре можно задать несколько важных параметров: нормализация – перевод отрезка [K,N] в отрезок [0,1], задаётся полем normalized объекта texture (значение true – выполнять нормализацию); преобразование адресов, если произошёл выход за пределы допустимого диапазона, поле addressMode объекта texture; способ фильтрации, если данные были заданы для целочисленных индексов, а доступ производится по индексам с плавающей точкой, поле filterMode объекта texture (cudaFilterModeLinear, если нужно выполнить интерполяцию и cudaFilterModePoint, если нужно возвращать значение ближайшей целочисленной координаты).
Для привязки текстуры к области глобальной памяти можно воспользоваться функцией __host__ cudaError_t cudaBindTexture ( size_t* offset, const texture < T, dim, readMode > & tex, const void* devPtr, const cudaChannelFormatDesc& desc, size_t size = UINT_MAX ), которая привязывает size байт начиная с адреса devPtr к текстуре tex. Параметр offset – адрес по которому записано смещение текстуры в памяти. Параметр desc – формат текстурного элемента (опциональный параметр). Функция __host__ cudaError_t cudaBindTexture2D ( size_t* offset, const texture < T, dim, readMode > & tex, const void* devPtr, const cudaChannelFormatDesc& desc, size_t width, size_t height, size_t pitch ) используется для привязки двумерных массивов. Параметры width и height – ширина и высота (в количестве текстурных элементов), pitch – количество байт использованных для выравнивания при отображении двумерного массива в линейную память. Обе функции связывают текстуры с линейной областью памяти.
Пример задания двумерной текстуры и связывания с линейной областью памяти:
texture<float, cudaTextureType2D,
        cudaReadModeElementType> texRef;
cudaChannelFormatDesc channelDesc =
                             cudaCreateChannelDesc<float>();
size_t offset;
cudaBindTexture2D(&offset, texRef, devPtr, channelDesc,
                  width, height, pitch);
При помощи функции cudaCreateChannelDesc создаётся объект формата текстурного элемента. В качестве параметра передаётся тип данных, который будет храниться в текстурных элементах.
Кроме линейной памяти текстуры можно привязывать к объектам типа cudaArray – тип данных представляющий массив, создан специально для работы с текстурами. Чтобы создать объект типа cudaArray нужно вызвать функцию __host__ cudaError_t cudaMallocArray ( cudaArray_t* array, const cudaChannelFormatDesc* desc, size_t width, size_t height = 0, unsigned int  flags = 0 ). Она выделяет память на устройстве размером width * height под текстуру с форматом desc. Параметр flags определяет какие дополнительные операции над текстурой можно производить. Функция __host__ cudaError_t cudaMalloc3DArray ( cudaArray_t* array, const cudaChannelFormatDesc* desc, cudaExtent extent, unsigned int  flags = 0 ) также создаёт объект cudaArray, но допускает от одного до трёх измерений.
Для привязки текстуры к объекту cudaArray нужно вызвать функцию __host__ cudaError_t cudaBindTextureToArray ( const texture < T, dim, readMode > & tex, cudaArray_const_t array, const cudaChannelFormatDesc& desc ) – связывает текстуру tex с объектом array формата desc.
Для считывания данных из текстур существует набор функций:
template<class T> T tex1Dfetch(cudaTextureObject_t texObj, int x) – считывает из линейной области памяти, связанного с одномерной текстурой данные, по целочисленной координате x. Работает только с ненормализованными координатами, фильтрация не выполняется.
template<class T> T tex1D(cudaTextureObject_t texObj, float x) – считывает данные из одномерной текстуры, ассоциированной с объектом cudaArray, по координате x.
template<class T> T tex2D(cudaTextureObject_t texObj, float x, float y) – считывает данные из двумерной текстуры, ассоциированной с объектом cudaArray, по координатам (x,y).
template<class T> T tex3D(cudaTextureObject_t texObj, float x, float y, float z); – считывает данные из трёхмерной текстуры, ассоциированной с объектом cudaArray, по координатам (x,y,z).
Пример демонстрирующий работу с двумерными текстурами:
// объявление двумерной текстуры
texture<float, cudaTextureType2D, cudaReadModeElementType> texRef;

__global__ void transformKernel(float* output,
                                int width, int height,
                                float theta) 
{
    // вычисление нормализованных координат
    unsigned int x = blockIdx.x * blockDim.x + threadIdx.x;
    unsigned int y = blockIdx.y * blockDim.y + threadIdx.y;

    float u = x / (float)width;
    float v = y / (float)height;

    // преобразование координат
    u -= 0.5f;
    v -= 0.5f;
    float tu = u * cosf(theta) - v * sinf(theta) + 0.5f;
    float tv = v * cosf(theta) + u * sinf(theta) + 0.5f;


    // считывание данных из текстуры и запись в глобальную память
    output[y * width + x] = tex2D(texRef, tu, tv);
}

int main()
{
    cudaChannelFormatDesc channelDesc =
               cudaCreateChannelDesc(32, 0, 0, 0,
                                     cudaChannelFormatKindFloat);
    cudaArray* cuArray;
    cudaMallocArray(&cuArray, &channelDesc, width, height);

    // Копирование данных из памяти хоста в объект cudaArray
    cudaMemcpyToArray(cuArray, 0, 0, h_data, size,
                      cudaMemcpyHostToDevice);

    // Установка параметров текстуры
    texRef.addressMode[0] = cudaAddressModeWrap;
    texRef.addressMode[1] = cudaAddressModeWrap;
    texRef.filterMode     = cudaFilterModeLinear;
    texRef.normalized     = true;

    // Привязка текстуры к объекту cudaArray
    cudaBindTextureToArray(texRef, cuArray, channelDesc);

    float* output;
    cudaMalloc(&output, width * height * sizeof(float));

    dim3 dimBlock(16, 16);
    dim3 dimGrid((width  + dimBlock.x - 1) / dimBlock.x,
                 (height + dimBlock.y - 1) / dimBlock.y);
    transformKernel<<<dimGrid, dimBlock>>>(output, width, height,
                                           angle);
    cudaFreeArray(cuArray);
    cudaFree(output);

    return 0;
}
Текстуры поддерживают четыре типа преобразования адресов: cudaAddressModeClamp – возвращает ближайшее значение при выходе за границы; cudaAddressModeBorder – возвращает значение левой границы при выходе за границу; cudaAddressModeWrap – зацикливает диапазон с периодом M; cudaAddressModeMirror – зацикливает допустимый диапазон с периодом 2 * M - 2. Последние два типа работают только с нормализованными координатами.
Пример различных типов преобразования адресов:
texture<float, 1, cudaReadModeElementType> texture_clamp;
texture<float, 1, cudaReadModeElementType> texture_border;
texture<float, 1, cudaReadModeElementType> texture_wrap;
texture<float, 1, cudaReadModeElementType> texture_mirror;

/********************/
/* CUDA ERROR CHECK */
/********************/
#define gpuErrchk(ans) { gpuAssert((ans), __FILE__, __LINE__); }
inline void gpuAssert(cudaError_t code, char *file, int line, bool abort=true)
{
    if (code != cudaSuccess) 
    {
        fprintf(stderr,"GPUassert: %s %s %d\n", cudaGetErrorString(code), file, line);
        if (abort) exit(code);
    }
}

/******************************/
/* CUDA ADDRESS MODE CLAMPING */
/******************************/
__global__ void Test_texture_clamping(const int M) {

    printf("Texture clamping - i = %i; value = %f\n", -threadIdx.x, tex1D(texture_clamp, -(float)threadIdx.x));
    printf("Texture clamping - i = %i; value = %f\n", M + threadIdx.x, tex1D(texture_clamp, (float)(M + threadIdx.x)));

}

/****************************/
/* CUDA ADDRESS MODE BORDER */
/****************************/
__global__ void Test_texture_border(const int M) {

    printf("Texture border - i = %i; value = %f\n", -threadIdx.x, tex1D(texture_border, -(float)threadIdx.x));
    printf("Texture border - i = %i; value = %f\n", M + threadIdx.x, tex1D(texture_border, (float)(M + threadIdx.x)));

}

/**************************/
/* CUDA ADDRESS MODE WRAP */
/**************************/
__global__ void Test_texture_wrap(const int M) {

    printf("Texture wrap - i = %i; value = %f\n", -threadIdx.x, tex1D(texture_wrap, -(float)threadIdx.x/(float)M));
    printf("Texture wrap - i = %i; value = %f\n", M + threadIdx.x, tex1D(texture_wrap, (float)(M + threadIdx.x)/(float)M));

}

/****************************/
/* CUDA ADDRESS MODE MIRROR */
/****************************/
__global__ void Test_texture_mirror(const int M) {

    printf("Texture mirror - i = %i; value = %f\n", -threadIdx.x, tex1D(texture_mirror, -(float)threadIdx.x/(float)M));
    printf("Texture mirror - i = %i; value = %f\n", M + threadIdx.x, tex1D(texture_mirror, (float)(M + threadIdx.x)/(float)M));

}

void main(){

    const int M = 4;
    float *h_data = (float*)malloc(M * sizeof(float));

    for (int i=0; i<M; i++) h_data[i] = (float)i;

    // --- Texture clamping
    cudaArray* d_data_clamping = NULL; gpuErrchk(cudaMallocArray(&d_data_clamping, &texture_clamp.channelDesc, M, 1)); 
    gpuErrchk(cudaMemcpyToArray(d_data_clamping, 0, 0, h_data, M * sizeof(float), cudaMemcpyHostToDevice)); 
    cudaBindTextureToArray(texture_clamp, d_data_clamping); 
    texture_clamp.normalized = false; 
    texture_clamp.addressMode[0] = cudaAddressModeClamp;

    dim3 dimBlock(2 * M, 1); dim3 dimGrid(1, 1);
    Test_texture_clamping<<<dimGrid,dimBlock>>>(M);

    printf("\n\n\n");

    // --- Texture border
    cudaArray* d_data_border = NULL; gpuErrchk(cudaMallocArray(&d_data_border, &texture_border.channelDesc, M, 1)); 
    gpuErrchk(cudaMemcpyToArray(d_data_border, 0, 0, h_data, M * sizeof(float), cudaMemcpyHostToDevice)); 
    cudaBindTextureToArray(texture_border, d_data_border); 
    texture_border.normalized = false; 
    texture_border.addressMode[0] = cudaAddressModeBorder;

    Test_texture_border<<<dimGrid,dimBlock>>>(M);

    printf("\n\n\n");

    // --- Texture wrap
    cudaArray* d_data_wrap = NULL; gpuErrchk(cudaMallocArray(&d_data_wrap, &texture_wrap.channelDesc, M, 1)); 
    gpuErrchk(cudaMemcpyToArray(d_data_wrap, 0, 0, h_data, M * sizeof(float), cudaMemcpyHostToDevice)); 
    cudaBindTextureToArray(texture_wrap, d_data_wrap); 
    texture_wrap.normalized = true; 
    texture_wrap.addressMode[0] = cudaAddressModeWrap;

    Test_texture_wrap<<<dimGrid,dimBlock>>>(M);

    printf("\n\n\n");

    // --- Texture mirror
    cudaArray* d_data_mirror = NULL; gpuErrchk(cudaMallocArray(&d_data_mirror, &texture_mirror.channelDesc, M, 1)); 
    gpuErrchk(cudaMemcpyToArray(d_data_mirror, 0, 0, h_data, M * sizeof(float), cudaMemcpyHostToDevice)); 
    cudaBindTextureToArray(texture_mirror, d_data_mirror); 
    texture_mirror.normalized = true ; 
    texture_mirror.addressMode[0] = cudaAddressModeMirror;

    Test_texture_mirror<<<dimGrid,dimBlock>>>(M);

    printf("\n\n\n");
}


Вывод:
index                  -7  -6  -5  -4  -3  -2  -1  0  1  2  3  4  5  6  7  8  9  10  11
clamp                   0   0   0   0   0   0   0  0  1  2  3  3  3  3  3  3  3   3   3
border                  0   0   0   0   0   0   0  0  1  2  3  0  0  0  0  0  0   0   0
wrap                    1   2   3   0   1   2   3  0  1  2  3  0  1  2  3  0  1   2   3
mirror                  1   2   3   3   2   1   0  0  1  2  3  3  2  1  0  0  1   2   3
[bookmark: header-n324]12. Заполняемость мультипроцессоров
В отличие от CPU, который задержку обращения к памяти пытается скрыть за счёт большого размера кэша, GPU скрывает задержку обращений в память за счёт большой степени параллелизма. Нити GPU очень легковесны и переключение контекстов происходит практически мгновенно. При любом обращении в глобальную память GPU мгновенно ставить на исполнение варп, нити которого готовы выполнять команды. Поэтому важно максимизировать количество варпов исполняемых мультипроцессором.
Заполняемость мультипроцессора – отношение фактического количества работающих варпов на мультипроцессоре к максимальному количеству поддерживаемых мультипроцессором варпов. Заполняемость зависит количества блоков, размера блоков, количества регистров, выделяемых на нить, количества разделяемой памяти и т.д. Для каждого устройства зная его спецификацию и параметры запуска задачи, можно рассчитать какой процент заполняемости будет достигнут при выполнении задачи на данном устройстве – этот параметр называется теоретической заполняемостью мультипроцессора. Например, пусть есть устройство со следующими параметрами:
Макс. варпов на мультипроцессор 64
Максимальное количество блоков на мультипроцессор 32
Регистры на мультипроцессор 65536
Разделяемая память на мультипроцессор (байт) 65536
Размер блока был выбран следующим: 128 нитей (= 4 варпа)
Теперь нужно рассчитать ограничения количества допустимых блоков по всем параметрам. Максимальное количество блоков, ограниченное размером блока = 64/4 = 16 блоков на SM. Разделяемая память на блок = 5000 байт. Макс. количество блоков, ограниченное общей памятью = 65536/5000 = 13,1 ~ 13 блоков. Регистров на нить = 48; на блок = 128 * 48 = 6144; максимальное количество блоков, ограниченное количеством регистров = 65536/6144 = 10,67 ~ 10 (ограничивающий параметр!). После того как нашли ограничивающий параметр переводим блоки в варпы и делим получившееся чило на максимально количество допустимых варпов на мультипроцессоре. Таким образом, теоретическая заполняемость составляет 10 * 4/64 = 40/64 = 0,625.
Для того чтобы повысить теоретическую заполняемость нужно попытаться изменить параметры запуска программы – размер блока, количество регистров на нить и т.д.
Для того чтобы измерить реальную заполняемость можно воспользоваться профилировщиком. Для утилиты nvprof есть опция achieved_occupancy. Реальная заполняемость будет всегда ниже теоретической за счёт того, что нельзя учесть все мельчайшие факторы при ручном расчёте.
Ранее было сказано, что все нити варпа выполняются физически одновременно. На самом деле это не совсем так. Есть некоторая функция-ядро:
__global__ void kernel () {
    int i = threadIdx.x + blockDim.x blockIdx.x;
    if (i % 2 == 0) {
        int a = i * 2;
    } else {
        int b = i - 4;
    }
}
Если эту функцию-ядро выполняет нить с чётным глобальным номером, то она проходит в ветку if, иначе в ветку else. Планировщик варпов работает таким образом, что выдаёт нитям варпа по две последовательных инструкции, которые должны быть одинаковыми для всех нитей. Для кода из примера выше это невозможно. В этом случае не все нити варпа будут работать параллельно. Сначала запустятся нити обрабатывающие ветку if и после того как они завершат обработку ветки, запустятся на исполнения нити обрабатывающие ветку else. Т.е. варп выполнится не за время t, а за время 2t, т.к. разделился на две части. Этот эффект называется дивергенция варпов. При написании кода с использованием технологии CUDA нужно стараться минимизировать количество условных переходов с веткой else. В коде ниже дивергенции варпов не возникает, потому что часть нитей варпа просто простаивает во время обработки условного перехода, а не ждёт своей очереди на исполнение:
__global__ void kernel () {
    int i = threadIdx.x + blockDim.x blockIdx.x;
    if (i % 2 == 0) {
        int a = i * 2;
    }
}
[bookmark: header-n336]Контрольные задания
Дана спецификация графического процессора: 
Максимальное число варпов на мультипроцессор: 32
Максимальное число блоков на мультипроцессор: 16
Максимальное количество 32-х битных регистров на мультипроцессор: 65536
Максимальное количество 32-х битных регистров на блок: 65536
Максимальное количество 32-х битных регистров на нить: 255
Размер разделяемой памяти мультипроцессора (байт): 65536
Размер разделяемой памяти блока (байт): 49152
Параметры запускаемой программы:
Размер блока: 32
Разделяемая память на блок (байт): 1000
32-х битных регистров на нить: 50
Чему равна теоретическая заполняемость? Какой фактор её ограничивает?
[bookmark: header-n348]13. Графы
Графы – новая модель организации работы в CUDA. Они представляют собой последовательность операций таких как запуск функции-ядра, подготовка зависимостей, связанных с её запуском, что позволяет один раз определить граф и множество раз запускать его повторно. Отделение определения графа позволяет произвести некоторые оптимизации таких как снижение накладных расходов на запуск функций-ядер или оптимизации, которые не могут быть достигнуты асинхронной передачей данных на устройство.
Когда запускается функция-ядро, драйвер выполняет подготовку к выполнению команд на GPU, что влечёт за собой определённые накладные расходы, которые будут возникать каждый запуск функции-ядра. Для маленьких по объёму функций-ядер время на подготовку может занимать весомую часть от общего времени выполнения.
Работа с графами разделена на три этапа. На первом этапе создаётся описание операций в графе и зависимости между ними. На втором этапе выполняется большая часть действий по настройке и инициализации работы с целью минимизировать подготовку запуска непосредственно перед ним самим. На третьем этапе граф можно запустить в каком-нибудь потоке на исполнение. При этом повторный запуск не требует повторной инициализации.
Узлы графа могут быть следующих типов: запуск функции-ядра, запуск функции хоста, копирование памяти, функции семейства memset, пустой узел, дочерний граф.
Пример создания графа:
cudaGraph_t graph;

cudaStreamBeginCapture(stream);

kernel_A<<< ..., stream >>>(...);
kernel_B<<< ..., stream >>>(...);
libraryCall(stream);
kernel_C<<< ..., stream >>>(...);

cudaStreamEndCapture(stream, &graph);
Действия выполняющиеся в потоке stream между вызовами функций cudaStreamBeginCaprure и cudaStreamEndCapture образуют граф.
image1.png
- =





image2.png




image3.png
SMX

Instruction Cache

4 Warp schedulers

Register file (65,536 x 32-bit)

c|c|c||orc||cfc|c||orc||wsT||srulfe]c|c||orc||cfc|c|]|orc||osT||sFu
c|c|c||oec||cfc|c||orc||wsT||srulfe]c|c||orc||c|c|c|]|orc||osT||sFu
c|c|c||oec||cfec|c||orc||wsT||sfulfe]ec|c||orc||c|ec|c|]|orc||osT||sFu
c|c|c||oec||cfec|c||orc||wsT||srulfe]c|c||orc||c|ec|ec|]|orc||osT||sFu
c|c|c||oec||efc|c||orc||wsT||sfulfe]ec|c||orc||c|c|c|]|orc||osT||sFu
c|c|c|[orc|[ele]c] orc|[wsr|[s| [ el e] [orc| [ e[| [orc|[omr| [srl
c|c|c||orc||cfc|c||orc||wssT||srulfe]c|c||orc||c|c|c|]|opc||osT||sFu
c|c|c||oec||cfec|c||opc||wssT||sfulfe]c|c||orc||c|c|c|]|opc||osT||sFu
c|c|c||orc||cfc|c||orc||wsT||srulfe]ec|c||orc||c|ec|c||orc||LosT||sFu
c|c|c||orc||cfc|c||opc||wsT||sfulfc]c|c||orc||c|c|c||orc||iosT||sFu
c|c|c||orc||cfec|c||opc||wsT||sfulfe]ec|c||orc||c|c|c|]|opc||osT||sFu
c|clc|[orc|[ele]c] orc|[wsr|[s| [ e ]| [orc| [ e e [orc| [ omt| [sru]
c|c|c||orc||cfc|c||orc||wsT||srulfe]ec|c||orc||c|c|c|]|opc||osT||sFu
c|c|c|[orc|[elc]c] orc|[wsr|[s| [ el e] [orc| [ e [c] [opc| [omr| [srul
c|c|c||oec||cfec|c||orc||wsT||sfulfe]c|c||orc||c|c|c|]|orc||osT||sFu
c|c|c||oec||efec|c||opc||wsT||srulfe]ec|c||orc||c|ec|ec|]|orc||osT||sFu
Interconnect Network
64KB Shared Memory / L1 Cache
48KB read-only data cache
Tex Tex Tex Tex
Tex Tex Tex Tex





image4.png
Grid





image5.png
CPU code

Grid

Block
thread 0,0| thread 0,1 | thread 0,2
thread 1,0 |thread 1,1 | thread 1,2





image6.png
GEEEEEED
o+
GEEEEEED




image7.png




image8.png
GEEEEEED
o+
GEEEEEED




image9.png
threadIdx.x threadIdx.x threadIdx.x threadIdx.x

112|3|4|5(6(7|0]|1|2(3(4|5|6|7(0(1]|2|3|4|5(|6(7|0|1|2(3|4|5|6

N7 N7 Y Y
blockIdx.x = 0 blockIdx.x = 1 blockIdx.x = 2 blockIdx.x = 3





image10.png
1711819 20.22 23|24

31’

threadIdx.x

blockIdx.x = 2




image11.png
r~
§
£
s
=
3
a
S





image12.png
=),

CPU Memory





image13.png
CPU

£
5
=
3
a
S





image14.png
O6palleHusa HUTel Bapna Bce o6palieHusn

=
I

512 = =

MopPAZOK He BakeH,
O6palueHna HUTet Bapna rnasHoe, 4tobbl nonaganu

\\M\ j\j\\x .





image15.png
OGpalieHnst HUTeH Bapna 3anpatwmsaetca 128 6aiiT, HO C He
BbIPOBHEHHOTO aapeca

\\\‘\\\\\\ \\\\\\\ 2 Tpar3aKLuy - 256 Gaiit
|

512, 640 =

3anpawwsaetca 128 6aiit, Ho
obpalueHuns pasbpocaHbl B
OGpaleHust HUTel Bapna npesenax Tpéx Kew-nmHum -

512 T =





image16.png
3anpawwmsaetca 128 6aitT, Ho ¢

O6paeHus HUTeH Bapma HeBbIPOBHEHHOTO aZpeca. YmellatoTcs B
yeTblpe Kew-anHum L2

\\\\\\\\\\\ \\‘\4\\\\ 4 TpaH3akuyy no 32 Gaiira — 128 Gaiir
L e ——r——

576

3anpawwmsaeTca 128 6aiiT, Ho
obpalleHmna pasbpocaHbl No NATU

OGpamieHns HUTel Bapna Kelw-nnMHuAm L2
5 TpaH3aKkuuii no 32 — 160 6ant

512 608 640 768




image17.png
OGpaleHust HUTe Bapna

e

abcabcabcabcabc,..abcabcabc




image18.png
OG6pareHust HUTel BapIa

a[a[a[a[a[a[a] - [b[s[b[b[b]b]b] -





image19.png
Bank0 Bank1 Bank2 Bank3 Bank28 Bank29 Bank30 Bank31

0 1 7
32 33 34
64 65 66
9% 97 98
128 | 129 | 130
160 | 161 | 162
192 | 193 | 194
224 | 225 |26

[

WHAeKcsl 32-X BUTHBIX Cnos

e00





image20.png
Serial Model

»
Time
Concurrent Model

Stream 1
Stream 2
Stream 3
Stream 4

)

Time




