
Цель и задачи работы
Цель работы: научиться строить синтаксические анализаторы для простых грамматик.
Задачи работы:
1. Изучить задание.
2. Построить модель грамматики в соответствии с заданием.
3. Разработать программу синтаксического анализа.
4. Разработать выполнение действий программой, в случае правильного ее написания.
Что надо сделать
После поворота событий от плохого к худшему цикл повторится.
Из законов Мэрфи
Целью выполнения данной работы является разработка программы-интерпретатора, которая анализирует программу на некотором входном языке с заданной грамматикой и определяет корректность этой программы. Интерпретатор должен отслеживать ошибки во входной программе и вести их протокол.
В качестве задания предлагается неформальное описание грамматики некоторого языка. На его основе следует:
1. Описать грамматику в виде диаграмм Вирта.
2. Описать грамматику в виде нормальной формы Бэкуса-Наура или в виде метасимволов.
3. Реализовать лексический анализатор для данной грамматики.
4. Реализовать подходящий синтаксический анализатор для данной грамматики.
5. Реализовать выполнение указанных действий над грамматикой. Рассмотрим следующий пример грамматики G языка L:
Язык арифметических выражений в инфиксной форме с операциями сложения и вычитания без скобок, с операндами в форме идентификаторов и целых констант.
Форму записи алгебраических выражений со знаком операции между операндами называют инфиксной (infix). Именно эта форма знакома нам со школы. Правила записи идентификаторов во всех заданиях соответствуют правилам языка Pascal
Таким образом, корректными выражениями на языке L будут: a+2; b_1-c2; 2+4.
Построение формальной грамматики
Не бойтесь совершенства, вы никогда его не достигнете.
Из законов Мэрфи
Наиболее простой способ описания грамматики языка – так называемые диаграммы Вирта. Эта форма была предложена при описании грамматики языка Pascal, а затем она получила широкое распространение в литературе. Она доступна не для всех типов грамматик, а только для тех типов, где в левой части правил присутствует не более одного символа, но этого достаточно, чтобы ее можно было использовать для описания грамма- тик известных языков программирования.
В такой форме записи каждому нетерминальному символу грамматики соответствует диаграмма, построенная в виде направленного графа. Граф имеет следующие типы вершин (рисунок 1):
1. точка входа (на диаграмме никак не обозначена, из нее просто начинается входная дуга графа);
2. нетерминальный символ (на диаграмме обозначается прямоугольником, в который вписано обозначение символа);
3. цепочка терминальных символов (на диаграмме обозначается овалом, кругом или прямоугольником с закругленными краями, внутрь которого вписана цепочка);
4. узловая точка (на диаграмме обозначается жирной точкой или закрашенным кружком);
5. точка выхода (никак не обозначена, в нее просто входит выходная дуга графа).

Рисунок 1 – Условные обозначения на синтаксических диаграммах
Каждая диаграмма имеет только одну точку входа и одну точку  выхода, но сколько угодно вершин других трех типов. Вершины  соединяются между собой направленными дугами графа (линиями со стрелками). Из входной точки дуги могут только выходить, а во входную точку - только входить. В остальные вершины дуги могут как входить, так и выходить (в правильно построенной грамматике каждая вершина должна иметь как минимум один вход и как минимум один выход).
Чтобы построить цепочку символов, соответствующую какому-либо корректному выражению языка надо, начав движение от точки входа, двигаться по дугам графа диаграммы через любые вершины вплоть до точки выхода. При этом, проходя через вершину, обозначенную нетерминальным символом, этот символ следует поместить в результирующую цепочку. При прохождении через вершину, обозначенную цепочкой терминальных символов, эти символы также следует поместить в результирующую  цепочку. При прохождении через узловые точки диаграммы над результирующей цепочкой никаких действии выполнять не надо. Через любую вершину графа диаграммы, в зависимости от возможного пути движения, можно пройти один раз, ни разу или сколь угодно много раз. Как только мы попадем в точку выхода диаграммы, построение результирующей цепочки будет закончено.
В   рассматриваемой  грамматике  терминальными  символами  будут являться:
1. знак "+";
2. знак "-";
3. литерал – символ "целое число", а нетерминальным символом – идентификатор.
Сначала построим диаграммы для нетерминальных символов и литералов. Описание литерала "целое число" потребует введения дополнительного нетерминального символа "цифра".
Опишем символ "идентификатор". Для этого понадобится ввести еще два нетерминальных символа: А1, включающий в себя те символы, с которых идентификатор может начинаться, и А2, включающий в себя те символы, которые в идентификаторе могут стоять на второй, третьей… позиции. Это связано с тем, что идентификатор не может начинаться с цифры, иначе он будет неотличим от символа "число" и грамматика окажется неоднозначной.

Выделим идентификатор и число в отдельный нетерминальный символ "слагаемое", а знаки "+" и "-" – в символ "операция":

Чтобы   можно   было   разбирать  выражения   произвольной  длины, необходимо предусмотреть "зацикливание" диаграммы:

Такой диаграмме соответствуют выражения вида: a; a + b; 10 + 20 - c; и т.д.
Теперь представим ту же грамматику в виде метасимволов. В качестве таких метасимволов используются следующие символы: ( ) (круглые скобки), [ ] (квадратные скобки), { } (фигурные скобки)," " (кавычки) и |  (вертикальная черта).
Эти метасимволы имеют следующий смысл:
1. круглые скобки означают, что из всех перечисленных внутри них цепочек символов в данном месте правила грамматики может стоять только одна цепочка;
2. квадратные скобки означают, что указанная в них цепочка может встречаться, а может и не встречаться в данном месте правила грамматики (то есть может быть в нем один раз или ни одного  раза);
3. фигурные скобки означают, что указанная внутри них цепочка может не встречаться в данном месте правила грамматики ни одного раза, встречаться один раз или сколь угодно много раз;
4. вертикальная черта служит для того, чтобы разделять цепочки символов внутри круглых скобок;
5. кавычки используются в тех случаях, когда один из метасимволов нужно включить в цепочку обычным образом - то есть когда одна из скобок или запятая должны присутствовать в цепочке символов языка (если саму кавычку нужно включить в цепочку символов, то ее надо повторить дважды).
Тогда грамматика примет вид:
<цифра> → ( 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 )
<число> → <цифра>{<цифра>}
<A1> → ( A | B | C | D … Z | _ )
<A2> → ( A | B | C | D … Z | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 | _ )
<идентификатор> → <A1>{<A2>}
<слагаемое> → (<идентификатор>|<число>)
<операция> → ( + | - )
<L> → < слагаемое>[{<операция><слагаемое>}]
Лексический анализ
Любой инструмент, если его уронят, закатывается в самый недоступный угол цеха.
Закатываясь в угол, он сначала ударит вас по пальцам ноги.
Из законов Мэрфи
При лексическом анализе текст выражения на языке L разделяется на отдельные лексемы. Лексема – это один терминальный или нетерминальный символ. В рассматриваемой грамматике лексический анализатор (ЛА) должен выделять лексемы следующих типов: идентификатор; число; "+"; "-", т.е. лексемы, непосредственно входящие в описание грамматики языка L. Результатом работы является динамический массив лексем.
Прежде всего опишем перечислимый тип данных, описывающий все возможные виды лексем:
TYPE TLexemeType=(NUMBER, ID, PLUS, MINUS, FINISH);
Константа FINISH соответствует концу анализируемого выражения и указывает на то, что за ней других лексем нет.
Опишем тип данных Tresult элемента выходного динамического массива:
TYPE Tres=RECORD
     lexeme:TLExemeType;
     value: LONGINT;
     name:STRING;
     position:WORD
  END;
TResult=ARRAY OF TRes;
Здесь в поле value хранится численное значение лексемы типа NUMBER, в поле name – имя лексемы-идентификатора типа ID, в поле position – позиция лексемы во входной строке (для индикации ошибок в программе).
Создадим теперь класс "Лексический анализатор":
TLexicalAnalyzer=CLASS
  PRIVATE
     Ferr:STRING;
     Flex:TResult;
     FUNCTION GetError:STRING;
     FUNCTION GetLex:TResult;
  PUBLIC
     CONSTRUCTOR Create;
     PROCEDURE Run(s:STRING);
     PROPERTY Error:STRING READ GetError;
     PROPERTY Lexem:
     TResult READ GetLex;
END;
Здесь введено свойство Error (только для чтения) для хранения в нем сообщений об ошибках, которые могут быть обнаружены в процессе анализа. В свойстве Lexem хранится собственно формируемый список лексем. Основным методом данного класса является функция Run, которая получает на вход выражение на языке L, а возвращает массив лексем. Реализация остальных методов тривиальна:
DESTRUCTOR TLexicalAnalyzer.Free;
BEGIN
     Finalize(Flex) // Удаление из памяти динамического массива
END;
CONSTRUCTOR TLexicalAnalyzer.Create;
BEGIN
     INHERITED Create;
     FErr:=''; SetLength(Flex,0) END;
FUNCTION TLexicalAnalyzer.GetError:STRING;
BEGIN
     Result:=Ferr
END;
А теперь самое интересное… Для упрощения кода внутри процедуры Run введена процедура addlex, добавляющая лексему в результирующий массив. Процедуры ReadID и ReadNumber считывают идентификаторы и числа соответственно. Для преобразования текса в число в процедуре ReadNumber применена стандартная функция StrToInt, для работы которой в операторе USES необходимо прописать ссылку на модуль SysUtils.
PROCEDURE TLexicalAnalyzer.Run(s:STRING); VAR i:WORD;
PROCEDURE addlex(l:TLexemeType; v:LONGINT; n:STRING);
BEGIN
  SetLength(FLex,Length(FLex)+1);
  WITH FLex[Length(FLex)-1] DO
   BEGIN
     Lexeme:=L;
     Value:=v;
     Name:=n;
     Position:=i
   END
END;
PROCEDURE ReadID; VAR n:STRING;
 BEGIN
   n:=s[i];
   INC(i);
   WHILE (i<=LENGTH(s)) AND (s[i] IN ['A'..'Z','_','0'..'9']) DO
     BEGIN
       n:=n+s[i];
       INC(i)
     END;
    AddLex(ID,0,n);
    DEC(i)
 END;
PROCEDURE ReadNumber;
VAR n:STRING;
 BEGIN
   n:=s[i];
   INC(i);
   WHILE (i<=LENGTH(s)) AND (s[i] IN ['0'..'9']) DO
     BEGIN
       n:=n+s[i];
       INC(i)
     END;
     AddLex(NUMBER,StrToInt(n),n);
     DEC(i)
 END;
 BEGIN
   i:=1;
   SetLength(Flex,0);
   Ferr:='';
   WHILE i<=LENGTH(s) DO
     BEGIN
       CASE s[i] OF
        '+': AddLex(PLUS,0,'+');
        '-': AddLex(MINUS,0,'-');
        'A'..'Z','_': ReadID;
        '0'..'9': ReadNumber
       ELSE
        BEGIN
          Ferr:='Недопустимый символ';
          Exit
        END
     END;
        INC(i)
 END;
 AddLex(FINISH,0,'')
END;
Cинтаксический анализ методом нисходящего разбора
Вывод - то место в тексте, где Вы устали думать.
Из законов Мэрфи
После получения списка лексем необходимо ответить на вопрос: в правильном ли порядке они идут? Из грамматики языка очевидно, что, к примеру, последовательность лексем ID – PLUS – NUMBER является верной, а последовательность ID – ID – MINUS – неверной. Программа-распознаватель должна ответить на вопрос, допустима ли предлагаемая последовательность лексем в рамках грамматики того или иного языка.
Существуют различные методы построения анализаторов. Один из основных – метод нисходящего разбора, при котором диаграмма Вирта фактически является блок-схемой процедур распознавания. Основная программа будет состоять из оператора чтения первой лексемы, за которым следует оператор активации основной цели грамматического разбора. Отдельные процедуры, соответствующие целям грамматического разбора или графам, получаются по следующим правилам.
Правила преобразования графа в программу:
1. Свести систему графов к как можно меньшему числу отдельных графов с помощью соответствующих подстановок.
2. Преобразовать каждый граф в  описание процедуры в соответствии с приведенными ниже правилами З - 7.
3. Последовательность элементов

переводится в составной оператор
begin T(S1); T(S2); ...; T(Sn) end
4. Выбор элементов

переводится в выбирающий или условный оператор
case ch of L1:T(S1);
if ch in L1 then T(S1)
else
if ch in L2 then T(S2)
else
где Li означает множество начальных символов нетерминального символа Si. Если Li состоит из одного символа a, то, разумеется, вместо ch in Li нужно писать ch = а.
5. Цикл вида:

переводится в оператор
while ch in L do T(S)
где T(S) есть отображение S в соответствии с правилами З-7, a L есть множество начальных символов нетерминального символа S  (см. предыдущее правило).
6. Элемент графа, обозначающий другой граф А

переводится в оператор обращения к процедуре А.
7. Элемент графа, обозначающий терминальный символ:

переводится в оператор
if ch = x then readlex (ch) else error
где error - процедура, к которой обращаются при появлении неправильной конструкции;
readlex(ch) – процедура чтения следующей лексемы в переменную ch.
Пример построения простого синтаксического анализатора
Независимо от того, куда вы едете,- это в гору и против ветра.
Из законов Мэрфи
Реализуем синтаксический анализатор в виде следующего класса:
type TSyntaxAnalyzer=CLASS
 PRIVATE
     FLex:TResult;  //  подаваемый  на  вход  массив лексем
     Ferr:STRING; // сообщение об ошибке Ferrpos:WORD; // позиция ошибки во  входной строке
     count:LONGINT; // номер текущей лексемы FUNCTION GetLex:TRes; // взять  следующую лексему из массива
     FUNCTION GetError:STRING;
     FUNCTION GetErrorPos:WORD;
 PUBLIC
     CONSTRUCTOR Create(ll:TResult);
     DESTRUCTOR Free;
     PROPERTY error:STRING READ GetError;
     PROPERTY errorpos:WORD READ GetErrorPos;
     PROCEDURE   Parse; // основная процедура разбора
 END;
Как видно, при создании объекта класса TSyntaxAnalyzer его конструктору на вход подается массив лексем, сформированный ранее лексическим анализатором. Реализация большинства методов синтаксического анализатора тривиальна:
CONSTRUCTOR TSyntaxAnalyzer.Create(ll:TResult);
  BEGIN
    INHERITED Create;
    Flex:=ll;
    count:=0;
    Ferr:='';
    Ferrpos:=0
 END;
     DESTRUCTOR TSyntaxAnalyzer.Free;
 BEGIN
     Finalize(Flex)
 END;
     FUNCTION TSyntaxAnalyzer.GetError:STRING;
 BEGIN
     Result:=self.Ferr
 END;
     FUNCTION TSyntaxAnalyzer.GetErrorPos:WORD;
  BEGIN
Result:=self.FErrPos END;
В методе GetLex в случае, если лексемы в массиве кончились, всегда возвращается лексема FINISH.
FUNCTION TSyntaxAnalyzer.GetLex:TRes;
 BEGIN
 IF count<=LENGTH(FLex)-1 THEN
   BEGIN
     Result:=Flex[count];
     INC(count)
   END
 ELSE
   WITH Result DO
     BEGIN
       Lexeme:=FINISH;
       name:='';
       value:=0;
       position:=0
     END
 END;
Самое сложное – процедура PARSE, отвечающая на вопрос соответствия заданной последовательности лексем грамматике языка. Ее алгоритм программируется в точном соответствии с правилом грамматики:
<L> à < слагаемое>[{<операция><слагаемое>}]
Для удобства введены два константных множества:
CONST operation=[PLUS, MINUS]; // операция item=[ID,NUMBER]; // слагаемое
Алгоритм имеет следующий вид:
PROCEDURE TSyntaxAnalyzer.Parse; VAR curlex:TRes; // текущая лексема
CONST operation=[PLUS, MINUS]; // операции
       item=[ID,NUMBER]; // слагаемое
BEGIN
  REPEAT
    curlex:=GetLex;
    IF curlex.lexeme IN item THEN // это слагаемое?
     BEGIN
       curlex:=GetLex;
       IF   curlex.lexeme=FINISH   THEN // еще есть лексемы?
         Exit; // нет - выходим
       REPEAT
         IF  curlex.lexeme  IN  Operation  THEN  //  это операция?
          BEGIN
            curlex:=GetLex;
            IF NOT(curlex.lexeme IN Item) THEN // это не слагаемое?
             BEGIN
               Ferr:='Синтаксическая ошибка. Ожидается слагаемое';
               Ferrpos:=curlex.position;
             Exit
             END
          END
         ELSE
          BEGIN
            Ferr:='Синтаксическая ошибка. Ожидается операция';
            Ferrpos:=curlex.position;
            Exit
          END;
        curlex:=GetLex;
     UNTIL curlex.lexeme=FINISH
   END
 UNTIL curlex.lexeme=FINISH
END;
Все! Легко убедиться, что данный синтаксический анализатор действительно корректно проверяет введенное выражение.
Собираем все вместе
Допустимые отклонения будут накапливаться однонаправленно,
чтобы причинить максимум трудностей при сборке.
Из законов Мэрфи
Давайте поместим на главную форму проекта поле ввода Edit1 и кнопку Button1 и напишем следующие обработчики событий:
глобальные переменные:
var
     LA:TLExicalAnalyzer;
     SA:TSyntaxAnalyzer;
создание формы:
procedure TForm1.FormCreate(Sender: TObject);
begin
     LA:=TLExicalAnalyzer.Create; // создали лексический анализатор
end;
закрытие формы:
procedure   TForm1.FormClose(Sender:   TObject;   var Action: TCloseAction);
begin
     LA.Free
end;
Обработка нажатия кнопки:
procedure TForm1.Button1Click(Sender: TObject);
var R:tresult; // список лексем
     mes:STRING;
begin
  SetLength(r,0);
  WITH LA DO
     BEGIN    
       Run(Trim(edit1.Text));   //  формирование  списка лексем
       IF Error='' THEN
        begin
         r:=Lexem;
         SA:=TSyntaxAnalyzer.Create(r); // создание СА
         SA.Parse; // разбор списка лексем
         IF SA.error='' THEN
          mes:='выражение корректное'
         ELSE
          BEGIN
            mes:=SA.error+'   (поз.
'+IntToStr(SA.errorpos)+')';
            WITH Edit1 DO
            BEGIN
             // выделение ошибки в поле ввода SetFocus;
             IF SA3.errorpos<Length(Edit1.Text) THEN SelStart:=SA3.errorpos
            ELSE
             SelStart:=Length(Edit1.Text)-1;
         SelLength:=1
      END
    END;
       MessageDlg(mes,mtInformation,[mbOK],0); SA.Free
      END
    ELSE
       MessageDlg(error,mtInformation,[mbOK],0);
 END
end;
Cинтаксический анализ методом построения конечного автомата
Лифт ломается чаще, чем лестница.
Из законов Мэрфи
Другой подход к анализу синтаксиса – представление его в виде графа переходов конечного автомата (КА). Преимущество такого подхода – простота реализации ("при программировании думать не надо"). Однако само построение КА – задача довольно нетривиальная, а для сложных грамматик – и невыполнимая. Для простых же грамматик построение КА позволяет резко упростить алгоритм разбора, реализация которого выполняется "не думая".
Каждой вершине графа соответствует нетерминальный символ грамматики. Кроме того, вводится дополнительная вершина (состояние) Е, соответствующее ошибке, и вершина Start как начальное состояние автомата. Алфавитом входных символов КА будет множество терминальных символов. Для рассматриваемого примера множество состояний автомата будет иметь вид: (<слагаемое> <операция> <ошибка>). На графе обозначим их как Item, Oper, Error соответственно. Теперь необходимо построить функцию переходов для каждого состояния, т.е. указать, в какое состояние переходит автомат при получении им на вход той или иной лексемы.
	Текущее состояние
	Символ на входе КА
	Новое состояние

	СЛАГАЕМОЕ
	СЛАГАЕМОЕ
	ОШИБКА

	
	ОПЕРАЦИЯ
	СЛАГАЕМОЕ

	ОПЕРАЦИЯ
	СЛАГАЕМОЕ
	ОПЕРАЦИЯ

	
	ОПЕРАЦИЯ
	ОШИБКА


Граф КА имеет следующий вид (рисунок 2):
[image: ]
Рисунок 2 – Граф переходов КА
Для программной реализации создадим класс-потомок класса TSyntaxAnalyzer. Чтобы потомок унаследовал все скрытые свойства и методы родителя, в описании класса TSyntaxAnalyzer заменим описание PRIVATE на PROTECTED. Разница в том, что свойства и методы в разделе PRIVATE не видны в классах-потомках, а в разделе PROTECTED – видны. Кроме того, надо позволить потомку перекрывать метод Parse, для чего объявим его как VIRTUAL. Тогда новый вариант объявления класса TSyntaxAnalyzer будет иметь вид:
[image: ]
Создаем  класс-потомок  с   единственным   новым   методом   Parse, перекрывающим собой одноименный метод родительского класса:
[image: ]
Реализация метода Parse как моделирование работы КА выполняется очень просто:
PROCEDURE TSyntaxAnalyzer2.Parse;
CONST oper=[PLUS, MINUS]; // операции
      item=[ID,NUMBER]; // слагаемые
// список состояний автомата
TYPE TState=(TSTART, TITEM, TOPER, TERROR);
VAR state:TState; // текущее состояние
     curlex:TRes; // текущая лексема
BEGIN
 state:=TSTART;
 REPEAT
   curlex:=GetLex;
   CASE state OF
   TSTART:
     IF curlex.lexeme IN oper THEN
       State:=TERROR
     ELSE
       IF curlex.lexeme IN item THEN
         State:=TITEM
       ELSE
         State:=TERROR;
   TITEM:
     IF curlex.Lexeme IN oper THEN
       state:=TOPER
     ELSE
       state:=TERROR;
   TOPER:
     IF curlex.Lexeme IN item THEN
       state:=TITEM
     ELSE
       state:=TERROR;
     END;
   UNTIL  (State=TERROR) OR (curlex.lexeme=FINISH);
IF (curlex.lexeme<>FINISH) THEN
   BEGIN
     Ferr:='Синтаксическая ошибка';
     FErrPos:=curlex.position
   END
END;
Анализаторы для сложных рекурсивных грамматик
Никогда не делайте ничего правильно с первого раза, иначе никто потом не оценит, как это было сложно.
Из законов Мэрфи
Следует заметить, что для более сложных случаев, когда в грамматике встречается рекурсия, т.е. какой-то нетерминальный символ определяется через самого себя, необходимо при нисходящем разборе создавать отдельные процедуры для обработки каждого такого символа. Скажем, язык целочисленных математических выражений со скобками и учетом приоритета операций определяется грамматикой:
<Expr> → <Term>{<Operator1><Term>}
<Term> → <Factor>{<Operator2><Factor>}
<Factor> → <Number>|'('<Expr>')'
<Operator1> → + | -
<Operator2> → * | /
(символ <Number> описывает грамматику целого числа и/или идентификатора и эквивалентен рассмотренному выше символу <Слагаемое>).
Здесь символ <Expr> неявно описан рекурсивно: в его определение входит символ <Factor>, в определение <Factor> входит символ <Term>, а в определение <Term> - снова <Expr>. Для реализации такого распознавателя нужно каждый нетерминальный символ выразить в виде отдельной процедуры.
Добавим в наш лексический анализатор возможность распознавания новых лексем:
TYPE TLexemeType=(NUMBER, ID, PLUS, MINUS, FINISH, MUL, DIVIDE,LP, RP);
Здесь MUL соответствует символу "*", DIVIDE – символу "/", LP – "(", RP – ")". Изменения в самом лексическом анализаторе очень просты – надо лишь добавить четыре строчки в процедуру Run:
CASE s[i] OF
     '+': AddLex(PLUS,0,'+');
     '-': AddLex(MINUS,0,'-');
     '*': AddLex(MUL,0,'*');
     '/': AddLex(DIVIDE,0,'/');
     '(': AddLex(LP,0,'(');
     ')': AddLex(RP,0,')');
     'A'..'Z','_': ReadID;
     '0'..'9': ReadNumber
А вот синтаксический анализатор придется писать заново. Как и в примере с КА, создадим его как потомка класса TSyntaxAnalyzer. Метод Parse будет иметь в совеем составе вложенные рекурсивно вызываемые процедуры, соответствующие нетерминальным символам:
PROCEDURE TSyntaxAnalyzer3.Parse;
CONST oper1=[PLUS, MINUS]; // операция1
      oper2=[MUL, DIVIDE]; // операция2
      item=[ID,NUMBER]; // слагаемое
VAR curlex:TRes;
PROCEDURE Term; FORWARD;
PROCEDURE Expr;
 BEGIN
   Term;
   WHILE curlex.lexeme IN oper1 DO
    BEGIN
     curlex:=GetLex;
     term
    END
 END;
 PROCEDURE Factor;
 BEGIN
  IF curlex.lexeme IN Item THEN
   BEGIN
     curlex:=GetLeX;
     Exit
   END;
  IF curlex.lexeme=LP THEN
   BEGIN
     curlex:=GetLeX;
     Expr;
     IF curlex.lexeme<>RP THEN
       BEGIN
         Ferr:='Непарные скобки';
         SELF.Ferrpos:=curlex.Position;
         Exit
       END
     ELSE
       curlex:=GetLex
    END
  ELSE
       BEGIN
         Ferr:='Синтаксическая ошибка';
         SELF.Ferrpos:=curlex.Position;
         Exit
       END
  END;
  PROCEDURE Term;
  BEGIN
    Factor;
    WHILE curlex.lexeme IN oper2 DO
     BEGIN
       curlex:=GetLex;
       Factor
     END
  END;
  BEGIN
     curlex:=GetLeX;  //  для  запуска  считываем  первую лексему
     Expr;
     IF Ferr<>'' THEN
     SELF.Ferrpos:=curlex.Position
  END;
Все процедуры (Expr, Term, Factor) описаны в полном соответствии с заданной грамматикой. Подобный анализатор корректно разбирает сложные выражения со вложенными скобками.
Вариант №7
Описать разными способами язык выражений с операциями логики языка Си, без скобок, с операндами в форме идентификаторов, операциями отношений. Операции отношений включают в себя двухоперандные арифметические выражения с идентификаторами и целыми константами.

